Version bump. Request bug #195262

Package-Manager: portage-2.1.3.16

1 files changed, 72 insertions, 0 deletions

diff --git a/media-libs/glfw/glfw-2.6.ebuild b/media-libs/glfw/glfw-2.6.ebuild
new file mode 100644
index 000000000000..c2a7b323a2a4
--- /dev/null
+++ b/media-libs/glfw/glfw-2.6.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/glfw/glfw-2.6.ebuild,v 1.1 2007/11/11 07:34:19 tupone Exp $
+
+inherit eutils
+
+DESCRIPTION="The Portable OpenGL FrameWork"
+HOMEPAGE="http://glfw.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+DEPEND="x11-libs/libXrandr
+	virtual/opengl"
+
+S=${WORKDIR}/${PN}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i \
+		-e "s:\"docs/:\"/usr/share/doc/${PF}/pdf/:" \
+		readme.html \
+		|| die "sed failed"
+	epatch "${FILESDIR}/${P}"-dyn.patch
+}
+
+src_compile() {
+	emake x11 || die "emake failed"
+}
+
+src_install() {
+	dolib.a lib/x11/libglfw.a || die "dolib.a failed"
+	dolib.so lib/x11/libglfw.so.2.6 || die "dolib.so failed"
+	dosym libglfw.so.2.6 /usr/lib/libglfw.so
+
+	insinto /usr/include/GL
+	doins include/GL/glfw.h || die "doins failed"
+	dohtml -r readme.html
+	insinto /usr/share/doc/${PF}/html/images
+	doins images/*
+	insinto /usr/share/doc/${PF}/pdf
+	doins docs/*.pdf
+
+	if use examples; then
+		local f
+		local MY_EXAMPLES="boing gears keytest listmodes mipmaps
+			mtbench mthello particles pong3d splitview
+			triangle wave"
+		local MY_PICS="mipmaps.tga pong3d_field.tga pong3d_instr.tga
+			pong3d_menu.tga pong3d_title.tga
+			pong3d_winner1.tga pong3d_winner2.tga"
+
+		insinto /usr/share/doc/${PF}/examples
+
+		doins examples/Makefile.x11
+		for f in $MY_EXAMPLES; do
+			doins examples/${f}.c
+		done
+		for f in $MY_PICS; do
+			doins examples/${f}
+		done
+
+		insopts -m0755
+		for f in $MY_EXAMPLES; do
+			doins examples/${f}
+		done
+	fi
+}