Version bump to fix build with gmake 3.82 (bug #336416, thanks to Kacper Kowalik and Peter Volkov); also update dependencies for libfpx (bug #334929, thanks to Nikoli).

Package-Manager: portage-2.2_rc86/cvs/Linux x86_64

3 files changed, 168 insertions, 2 deletions

diff --git a/media-gfx/imagemagick/ChangeLog b/media-gfx/imagemagick/ChangeLog
index 20f818d50fff..108a65a3d533 100644
--- a/media-gfx/imagemagick/ChangeLog
+++ b/media-gfx/imagemagick/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-gfx/imagemagick
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/ChangeLog,v 1.413 2010/09/14 21:25:21 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/ChangeLog,v 1.414 2010/09/23 15:17:59 flameeyes Exp $
+
+*imagemagick-6.6.4.5 (23 Sep 2010)
+
+  23 Sep 2010; Diego E. Pettenò <flameeyes@gentoo.org>
+  +imagemagick-6.6.4.5.ebuild:
+  Version bump to fix build with gmake 3.82 (bug #336416, thanks to Kacper
+  Kowalik and Peter Volkov); also update dependencies for libfpx (bug
+  #334929, thanks to Nikoli).
 
   14 Sep 2010; Tobias Klausmann <klausman@gentoo.org>
   imagemagick-6.6.2.5.ebuild:
diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index 7aac48ad484f..390149a30f67 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -1,8 +1,20 @@
+-----BEGIN PGP SIGNED MESSAGE-----
+Hash: SHA1
+
 DIST ImageMagick-6.6.1-2.tar.xz 6231544 RMD160 8c87f76764356640a86dcaf4c5eb9d2caf94c243 SHA1 c57d80607a4a4b90e10e718f95cde380915169a7 SHA256 e510045d6aca949092f696b6b4e2994cf22693408f067e4ae9a00f66c414910a
 DIST ImageMagick-6.6.2-5.tar.xz 6469864 RMD160 4d53b8d20b27147affebfb703e8996ab8b28d8ac SHA1 8a803b5e29901e4aba44d3f6561686926d5a1817 SHA256 4cbf14efa8076717bd7de19dc2db398ec24c28452d0b1f2a8ebfe9876342c838
 DIST ImageMagick-6.6.3-0.tar.xz 6291300 RMD160 64db0749fc0e407fbed1cb0a9bfeca499f8c0618 SHA1 1bb7b98de4b3eebb8c3927d52169b2f773bb40f1 SHA256 f37c15dfd40389788b93898b8f1cdde1e5bcc477dc5e496e8a5f93c56c9bcbba
+DIST ImageMagick-6.6.4-5.tar.xz 6278612 RMD160 17d62fe7f5c74c3758e8679240d190beab429521 SHA1 e180af21fc9c8b8f8828425c3547c7d812350d4c SHA256 3363e014099a59814270b29fddfb5875d89e1de2ef3c3c01a1aecbf8150cd57c
 EBUILD imagemagick-6.6.1.2.ebuild 3827 RMD160 11df027e97ad49e526b8e7cd472aed446048ffd3 SHA1 bb82c14c190f10923cdbd68aaa3957ee9cfa740f SHA256 8f4fd196f33962b3bc8b1a9c7182228a102187e1b1986c23b8d28c42733cb60e
 EBUILD imagemagick-6.6.2.5.ebuild 3924 RMD160 b645c76807a6c2a0b3bfe5fd968555bfbd076578 SHA1 000d54899604aec180efb5b97cf738afcc84305f SHA256 68eda8bed46b8c6cf4d0163757cb2911b56d17e38c6b3a68654a063f14961278
 EBUILD imagemagick-6.6.3.0.ebuild 4107 RMD160 8faf6a766534639863043b6fc57fdc06d9477513 SHA1 b5e4d1ca4b2f5947492e3fc8abeac82c5a33829a SHA256 b9400009249be30b4cc0dd447f745d4d4bce523d3931e3d44a0fd55d2d9fd9d7
-MISC ChangeLog 61299 RMD160 bf2898e997381076314448c28b176f0061b5173e SHA1 ed1b63931c435be1f0d6f27b79d7550e0592526d SHA256 d11c0210023c9cccc73e4bab758d447aeececaf7af01140b13c98a9ebf00fefb
+EBUILD imagemagick-6.6.4.5.ebuild 4118 RMD160 f442a274c766fbab68f7c5aa8a746b2323766434 SHA1 1c22732890ca55894777f267064de4a9ee22016c SHA256 fb111f66d173a057a7cc727af5c47c00386111ac62b8ed8a7385130517e44bc6
+MISC ChangeLog 61599 RMD160 2756ef15419f7d5392d66445f7a834e0c671a67c SHA1 97a00178cdb7da4ffabcb5733f8372a1eb027bce SHA256 ce50aaff2b08413363439c2819f2afd604ff0ece290eb937c9850fcd969acd56
 MISC metadata.xml 814 RMD160 0563719e5dfd793fa265434bd366f6d6c784ad37 SHA1 e7a6737a04c43c0d0b9d4b087f661122fe28d578 SHA256 0b2915134cbcdda31fc0b579d661fa9e0afd2354dcf7773b71d54b0f65f33cb9
+-----BEGIN PGP SIGNATURE-----
+Version: GnuPG v2.0.16 (GNU/Linux)
+
+iEYEARECAAYFAkybb98ACgkQAiZjviIA2XiDqQCgwgEBvbLdCpgXGFgfQXnzCgzt
+XGQAmgM6CKd5egkz4C/IVIxoHI9FnVW9
+=7R7j
+-----END PGP SIGNATURE-----
diff --git a/media-gfx/imagemagick/imagemagick-6.6.4.5.ebuild b/media-gfx/imagemagick/imagemagick-6.6.4.5.ebuild
new file mode 100644
index 000000000000..f49181a603bf
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-6.6.4.5.ebuild
@@ -0,0 +1,146 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/imagemagick-6.6.4.5.ebuild,v 1.1 2010/09/23 15:17:59 flameeyes Exp $
+
+EAPI=3
+inherit multilib toolchain-funcs versionator
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="autotrace bzip2 +corefonts cxx djvu fftw fontconfig fpx graphviz gs hdri jbig jpeg jpeg2k lcms lqr openexr openmp perl png q32 q8 raw static-libs svg tiff truetype wmf X xml zlib"
+IUSE="${IUSE} video_cards_nvidia" # opencl support
+
+RDEPEND=">=sys-devel/libtool-2.2.6b
+	autotrace? ( >=media-gfx/autotrace-0.31.1 )
+	bzip2? ( app-arch/bzip2 )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( >=media-gfx/graphviz-2.6 )
+	gs? ( app-text/ghostscript-gpl )
+	jbig? ( media-libs/jbigkit )
+	jpeg? ( virtual/jpeg )
+	jpeg2k? ( media-libs/jasper )
+	lcms? ( =media-libs/lcms-2* )
+	lqr? ( >=media-libs/liblqr-0.1.0 )
+	openexr? ( media-libs/openexr )
+	perl? ( >=dev-lang/perl-5.8.6-r6 )
+	png? ( >=media-libs/libpng-1.4 )
+	raw? ( media-gfx/ufraw )
+	svg? ( >=gnome-base/librsvg-2.9.0 )
+	tiff? ( >=media-libs/tiff-3.5.5 )
+	truetype? ( =media-libs/freetype-2*
+		corefonts? ( media-fonts/corefonts ) )
+	video_cards_nvidia? ( x11-drivers/nvidia-drivers )
+	wmf? ( >=media-libs/libwmf-0.2.8 )
+	X? (
+		x11-libs/libXext
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM
+	)
+	xml? ( >=dev-libs/libxml2-2.4.10 )
+	zlib? ( sys-libs/zlib )
+	!dev-perl/perlmagick
+	!media-gfx/graphicsmagick[imagemagick]"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	>=sys-apps/sed-4
+	X? ( x11-proto/xextproto )"
+
+S=${WORKDIR}/${MY_P}
+
+RESTRICT="perl? ( userpriv )"
+
+src_prepare() {
+	sed -i \
+		-e "/^DOCUMENTATION_RELATIVE_PATH/s:=.*:=${PF}:" \
+		configure || die
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	local openmp=disable
+	if use openmp && tc-has-openmp; then
+		openmp=enable
+	fi
+
+	local myconf
+	if use truetype; then
+		myconf="$(use_with corefonts windows-font-dir /usr/share/fonts/corefonts)"
+	else
+		myconf="--without-corefonts"
+	fi
+
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable static-libs static) \
+		$(use_enable hdri) \
+		$(use_enable video_cards_nvidia opencl) \
+		--with-threads \
+		--without-included-ltdl \
+		--with-ltdl-include="${EPREFIX}/usr/include" \
+		--with-ltdl-lib="${EPREFIX}/usr/$(get_libdir)" \
+		--with-modules \
+		--with-quantum-depth=${depth} \
+		$(use_with cxx magick-plus-plus) \
+		$(use_with perl) \
+		--with-perl-options='INSTALLDIRS=vendor' \
+		--with-gs-font-dir="${EPREFIX}/usr/share/fonts/default/ghostscript" \
+		$(use_with bzip2 bzlib) \
+		$(use_with X x) \
+		$(use_with zlib) \
+		$(use_with autotrace) \
+		$(use_with gs dps) \
+		$(use_with djvu) \
+		--with-dejavu-font-dir="${EPREFIX}/usr/share/fonts/dejavu" \
+		$(use_with fftw) \
+		$(use_with fpx) \
+		$(use_with fontconfig) \
+		$(use_with truetype freetype) \
+		$(use_with gs gslib) \
+		$(use_with graphviz gvc) \
+		$(use_with jbig) \
+		$(use_with jpeg) \
+		$(use_with jpeg2k jp2) \
+		--without-lcms \
+		$(use_with lcms lcms2) \
+		$(use_with lqr) \
+		$(use_with openexr) \
+		$(use_with png) \
+		$(use_with svg rsvg) \
+		$(use_with tiff) \
+		${myconf} \
+		$(use_with wmf) \
+		$(use_with xml) \
+		--${openmp}-openmp
+}
+
+src_test() {
+	if has_version ~${CATEGORY}/${P}; then
+		emake -j1 check || die
+	else
+		ewarn "Skipping tests because installed version doesn't match."
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS.txt ChangeLog NEWS.txt README.txt
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -delete
+		find "${ED}" -depth -mindepth 1 -type d -empty -delete
+	fi
+}