Version bump. Fixes some png, tiff... regressions

Package-Manager: portage-2.2.0_alpha108/cvs/Linux x86_64

3 files changed, 172 insertions, 6 deletions

diff --git a/media-gfx/imagemagick/ChangeLog b/media-gfx/imagemagick/ChangeLog
index 77f628e3611f..5930104bd06f 100644
--- a/media-gfx/imagemagick/ChangeLog
+++ b/media-gfx/imagemagick/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/imagemagick
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/ChangeLog,v 1.481 2012/05/13 17:22:50 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/ChangeLog,v 1.482 2012/06/01 07:43:06 ssuominen Exp $
+
+*imagemagick-6.7.7.5 (01 Jun 2012)
+
+  01 Jun 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +imagemagick-6.7.7.5.ebuild:
+  Version bump.
 
   13 May 2012; Fabian Groffen <grobian@gentoo.org> imagemagick-6.7.6.9.ebuild:
   Fix out of Prefix errors, run elibtoolize for Darwin modules
diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index c0e7750039a7..b6be36d9c6ff 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -3,14 +3,20 @@ Hash: SHA1
 
 DIST ImageMagick-6.7.6-4.tar.xz 7576636 RMD160 f8f75421e62ae9808bf8b1b549b1ec4ee92f40a7 SHA1 e349c0976d87d8897f9d6fc3d9efee6062ec0f4d SHA256 612910aca97c345e21901cb3b2b45b485029f196d02c3c42fc3354fc824b811e
 DIST ImageMagick-6.7.6-9.tar.xz 7653436 RMD160 0762ef3b40a7fda5c42ff2a2727ff74104cceae6 SHA1 4577fcabab5e754a777db874692587e26e6a2696 SHA256 4ce906ce36622a864746cf808fd14f9deba0eb6b6890c00e5832323e8c868e5c
+DIST ImageMagick-6.7.7-5.tar.xz 7602596 RMD160 0617338c6234f08793d2f053c5dcac542731ffca SHA1 44b307c97c9bc27f60963306c82e2de5e37dcfb5 SHA256 5a978f28e4e4e8f5a5d553fa0a673beccc440ce9bd5119a26464f63168cba714
 EBUILD imagemagick-6.7.6.4.ebuild 4188 RMD160 c8a14f4d5c6b091b9c320e48e0d51b5033f27bc4 SHA1 5120e6e90a54fea0c69d97f9288d1903f0f7cc78 SHA256 e11eb8cda888c670a42396b993c2df7b1a0208c51c6f0d72b6126fb17cc5e148
 EBUILD imagemagick-6.7.6.9.ebuild 4303 RMD160 be4c4cc9eddc2d2278dd01442c7f7a704f25767e SHA1 6d1789777871bfd1a740cde86c347dcb67c14ff1 SHA256 594c27cdd3de052cf2df79b0620ed644e4133f7348d6183aecdf81eff309f59a
-MISC ChangeLog 71248 RMD160 887a66fbede5dde89bc7e7e0560657db5f18da01 SHA1 1b6e2477edec2044ee1a8ceec35366014c62402d SHA256 5c12a96c2a8e027cc228c2f765fa0e1e574602c4396a03d873d94df985dcaa8f
+EBUILD imagemagick-6.7.7.5.ebuild 4305 RMD160 d57b45e0e63f41471499b74abc443589c9a57435 SHA1 edd5219f4f20f03f5d45525a66e9f9291037d026 SHA256 a6bf110597f3475af9b286d40998002755c06ff38767d634cd4c29c7b025b805
+MISC ChangeLog 71388 RMD160 708e4ad3ab6b1a0b5cc3b5c744908475b78eef64 SHA1 9966446973c9fdab8a4341484137099a847449d6 SHA256 c3f459e787565ea12dfda81065a76ca3b41eba701a39a31eb8f9581beada6bcf
 MISC metadata.xml 1104 RMD160 a1e2500c6057d9aaac9424ec72dc099da042e1ee SHA1 4ad8f34e03f649808dfa3999d60497c56722cee8 SHA256 d6840b362278ffdced22382075ebd20652f1b82470b6b9cbd035c4fc9ece60d3
 -----BEGIN PGP SIGNATURE-----
-Version: GnuPG v2.0.19 (Darwin)
+Version: GnuPG v2.0.19 (GNU/Linux)
 
-iEYEARECAAYFAk+v7fAACgkQX3X2B8XHTolgNgCeJEEXyNEXihxx2ZvjjYoPUU2p
-VF0An2Mod12mKBZlMovlNdefY5uRKoZ9
-=T4Cf
+iQEcBAEBAgAGBQJPyHGqAAoJEEdUh39IaPFNnycH/iKhncgemGP/dFxkJELxevFl
+cW+BUxDGhdk/I71ZHc5EsqRf584f0b1BvQdJ0yYVmq0R5RHore30/CadVVIEL6tK
+0BWtmS2KHQQE7LsL5MIpCGQOZ4EWbnzpF9IFBiV8xlp40r6VxB8nfZBuuoXju7eC
+pA89hvuuO+SkuC1clPrG0BTVTwSHzz8gCgYtVQJ9f9U2BMy+UFxJ4H9pIyKNYDmJ
+3YX9nsGVm0SfB8wnN33UbvzmXL96Xof7d8mOYr6hakkso72fbuasYTQ5Z/ByMBIk
+LIWNrViHFlqSF8Zdf7o7qOFd+ScSApNXJMQgP1rmcEBdMvrGAqXsAjIuvPdbQEI=
+=zP2P
 -----END PGP SIGNATURE-----
diff --git a/media-gfx/imagemagick/imagemagick-6.7.7.5.ebuild b/media-gfx/imagemagick/imagemagick-6.7.7.5.ebuild
new file mode 100644
index 000000000000..995266a61948
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-6.7.7.5.ebuild
@@ -0,0 +1,154 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/imagemagick-6.7.7.5.ebuild,v 1.1 2012/06/01 07:43:06 ssuominen Exp $
+
+EAPI=4
+inherit multilib toolchain-funcs versionator libtool
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="autotrace bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz gs hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png q32 q64 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND=">=sys-devel/libtool-2.2.6b
+	autotrace? ( >=media-gfx/autotrace-0.31.1 )
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( >=media-gfx/graphviz-2.6 )
+	gs? ( app-text/ghostscript-gpl )
+	jbig? ( media-libs/jbigkit )
+	jpeg? ( virtual/jpeg )
+	jpeg2k? ( media-libs/jasper )
+	lcms? ( media-libs/lcms:2 )
+	lqr? ( >=media-libs/liblqr-0.1.0 )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.6-r6 )
+	png? ( media-libs/libpng:0 )
+	raw? ( media-gfx/ufraw )
+	svg? ( >=gnome-base/librsvg-2.9.0 )
+	tiff? ( media-libs/tiff:0 )
+	truetype? (
+		media-libs/freetype:2
+		media-fonts/urw-fonts
+	)
+	webp? ( media-libs/libwebp )
+	wmf? ( >=media-libs/libwmf-0.2.8 )
+	X? (
+		x11-libs/libXext
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM
+	)
+	xml? ( >=dev-libs/libxml2-2.4.10 )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	app-arch/xz-utils
+	virtual/pkgconfig
+	>=sys-apps/sed-4
+	X? ( x11-proto/xextproto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	elibtoolize # for Darwin modules
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+	use q64 && depth=64
+
+	local openmp=disable
+	if use openmp && tc-has-openmp; then
+		openmp=enable
+	fi
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable hdri) \
+		$(use_enable opencl) \
+		--with-threads \
+		--without-included-ltdl \
+		--with-ltdl-include="${EPREFIX}/usr/include" \
+		--with-ltdl-lib="${EPREFIX}/usr/$(get_libdir)" \
+		--with-modules \
+		--with-quantum-depth=${depth} \
+		$(use_with cxx magick-plus-plus) \
+		$(use_with perl) \
+		--with-perl-options='INSTALLDIRS=vendor' \
+		--with-gs-font-dir="${EPREFIX}/usr/share/fonts/urw-fonts" \
+		$(use_with bzip2 bzlib) \
+		$(use_with X x) \
+		$(use_with zlib) \
+		$(use_with autotrace) \
+		$(use_with gs dps) \
+		$(use_with djvu) \
+		--with-dejavu-font-dir="${EPREFIX}/usr/share/fonts/dejavu" \
+		$(use_with fftw) \
+		$(use_with fpx) \
+		$(use_with fontconfig) \
+		$(use_with truetype freetype) \
+		$(use_with gs gslib) \
+		$(use_with graphviz gvc) \
+		$(use_with jbig) \
+		$(use_with jpeg) \
+		$(use_with jpeg2k jp2) \
+		--without-lcms \
+		$(use_with lcms lcms2) \
+		$(use_with lqr) \
+		$(use_with lzma) \
+		$(use_with openexr) \
+		$(use_with pango) \
+		$(use_with png) \
+		$(use_with svg rsvg) \
+		$(use_with tiff) \
+		$(use_with webp) \
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts) \
+		$(use_with wmf) \
+		$(use_with xml) \
+		--${openmp}-openmp
+}
+
+src_test() {
+	if has_version ~${CATEGORY}/${P}; then
+		emake -j1 check
+	else
+		ewarn "Skipping testsuite because installed version doesn't match."
+	fi
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}/usr/share/doc/${PF}" \
+		install
+
+	dodoc {AUTHORS,NEWS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+}