Version bump KDE SC 4.14.0

Package-Manager: portage-2.2.12/cvs/Linux x86_64
Manifest-Sign-Key: 0xF3CFD2BD

1 files changed, 72 insertions, 0 deletions

diff --git a/kde-base/korundum/korundum-4.14.0.ebuild b/kde-base/korundum/korundum-4.14.0.ebuild
new file mode 100644
index 000000000000..16c385fad4ee
--- /dev/null
+++ b/kde-base/korundum/korundum-4.14.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/korundum-4.14.0.ebuild,v 1.1 2014/08/20 16:02:51 johu Exp $
+
+EAPI=5
+
+OPENGL_REQUIRED="always"
+
+USE_RUBY="ruby19"
+# Only one ruby version is supported:
+# 1) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
+# 2) the ebuild can only be installed for one ruby variant, otherwise the compiled
+#    files with identical path+name will overwrite each other - difficult :(
+
+inherit kde4-base ruby-ng
+
+DESCRIPTION="KDE Ruby bindings"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="akonadi debug kate nepomuk okular"
+HOMEPAGE="http://techbase.kde.org/Development/Languages/Ruby"
+
+DEPEND="
+	$(add_kdebase_dep qtruby)
+	$(add_kdebase_dep smokekde 'akonadi?,kate?,okular?,nepomuk?')
+	$(add_kdebase_dep smokeqt)
+"
+RDEPEND="${DEPEND}
+"
+
+pkg_setup() {
+	ruby-ng_pkg_setup
+	kde4-base_pkg_setup
+}
+
+src_unpack() {
+	local S="${WORKDIR}/${P}"
+	kde4-base_src_unpack
+
+	cd "${WORKDIR}"
+	mkdir all
+	mv ${P} all/ || die "Could not move sources"
+}
+
+all_ruby_prepare() {
+	kde4-base_src_prepare
+}
+
+each_ruby_configure() {
+	CMAKE_USE_DIR=${S}
+	local mycmakeargs=(
+		-DRUBY_LIBRARY=$(ruby_get_libruby)
+		-DRUBY_INCLUDE_PATH=$(ruby_get_hdrdir)
+		-DRUBY_EXECUTABLE=${RUBY}
+		$(cmake-utils_use_with akonadi)
+		$(cmake-utils_use_with akonadi KdepimLibs)
+		$(cmake-utils_use_with nepomuk)
+		$(cmake-utils_use_with nepomuk Soprano)
+		$(cmake-utils_use_disable kate)
+		$(cmake-utils_use_with okular)
+	)
+	kde4-base_src_configure
+}
+
+each_ruby_compile() {
+	CMAKE_USE_DIR=${S}
+	kde4-base_src_compile
+}
+
+each_ruby_install() {
+	CMAKE_USE_DIR=${S}
+	kde4-base_src_install
+}