Version bump to 0.10.1. Bug #135667

Package-Manager: portage-2.1.1

1 files changed, 51 insertions, 0 deletions

diff --git a/games-strategy/attal/attal-0.10.1.ebuild b/games-strategy/attal/attal-0.10.1.ebuild
new file mode 100644
index 000000000000..2d6ed2da3911
--- /dev/null
+++ b/games-strategy/attal/attal-0.10.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/attal/attal-0.10.1.ebuild,v 1.1 2006/09/11 21:19:38 tupone Exp $
+
+inherit qt4 eutils games
+
+MY_P="${PN}-src-${PV}"
+DESCRIPTION="turn-based strategy game project"
+HOMEPAGE="http://www.attal-thegame.org/"
+SRC_URI="mirror://sourceforge/attal/${MY_P}.tar.bz2
+	mirror://sourceforge/attal/themes-${PV}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~ppc ~x86"
+IUSE=""
+
+DEPEND="$(qt4_min_version 4)
+	media-libs/sdl-mixer"
+
+S=${WORKDIR}/${MY_P}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	mv ../themes .
+	find . -name .cvsignore -print0 | xargs -0 rm -f
+	epatch "${FILESDIR}"/${P}-{gcc41,gentoo}.patch
+	sed -i \
+		-e "s:@GENTOO_DATADIR@:${GAMES_DATADIR}/${PN}:" \
+		libCommon/displayHelp.cpp \
+		libCommon/attalCommon.cpp \
+		server/duel.cpp \
+		|| die "sed failed"
+
+	qmake -o Makefile Makefile.pro || die "qmake failed"
+}
+
+src_compile() {
+	emake -j1 || die "emake failed" #disable parallel builds
+}
+
+src_install() {
+	dogamesbin attal-* || die "dogamesbin failed"
+	dogameslib.so lib*.so* || die "dogameslib.so failed"
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins HOWTOPLAY.html
+	doins -r themes || die "doins themes failed"
+	dodoc AUTHORS NEWS README TODO
+	prepgamesdirs
+}