Version bump for #258830.

Package-Manager: portage-2.2_rc25/cvs/Linux x86_64

1 files changed, 55 insertions, 0 deletions

diff --git a/app-admin/metalog/metalog-1.ebuild b/app-admin/metalog/metalog-1.ebuild
new file mode 100644
index 000000000000..fbdd290a4e05
--- /dev/null
+++ b/app-admin/metalog/metalog-1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/metalog/metalog-1.ebuild,v 1.1 2009/03/15 11:04:03 vapier Exp $
+
+inherit eutils
+
+DESCRIPTION="A highly configurable replacement for syslogd/klogd"
+HOMEPAGE="http://metalog.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.lzma"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND=">=dev-libs/libpcre-3.4"
+DEPEND="${RDEPEND}
+	app-arch/lzma-utils"
+PROVIDE="virtual/logger"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}"/${PN}-0.9-metalog-conf.patch
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dodoc AUTHORS ChangeLog README NEWS metalog.conf
+
+	into /
+	dosbin "${FILESDIR}"/consolelog.sh || die
+
+	newinitd "${FILESDIR}"/metalog.initd metalog
+	newconfd "${FILESDIR}"/metalog.confd metalog
+}
+
+pkg_preinst() {
+	if [[ -d "${ROOT}"/etc/metalog ]] && [[ ! -e "${ROOT}"/etc/metalog.conf ]] ; then
+		mv -f "${ROOT}"/etc/metalog/metalog.conf "${ROOT}"/etc/metalog.conf
+		rmdir "${ROOT}"/etc/metalog
+		export MOVED_METALOG_CONF=true
+	else
+		export MOVED_METALOG_CONF=false
+	fi
+}
+
+pkg_postinst() {
+	if ${MOVED_METALOG_CONF} ; then
+		ewarn "The default metalog.conf file has been moved"
+		ewarn "from /etc/metalog/metalog.conf to just"
+		ewarn "/etc/metalog.conf.  If you had a standard"
+		ewarn "setup, the file has been moved for you."
+	fi
+}