blob: b4d8bf68db8fb4134716c7f04a68b2d3d0ecdb96 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Copyright 2021-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit meson python-any-r1
DESCRIPTION="D-Bus service to check the availability of dual-GPU"
HOMEPAGE="https://gitlab.freedesktop.org/hadess/switcheroo-control/"
SRC_URI="https://gitlab.freedesktop.org/hadess/switcheroo-control/uploads/86ea54ac7ddb901b6bf6e915209151f8/${P}.tar.xz"
LICENSE="GPL-3"
SLOT="0"
IUSE="gtk-doc test"
KEYWORDS="amd64"
RDEPEND="
>=dev-libs/glib-2.56.0:2
>=dev-libs/libgudev-232:=
sys-apps/systemd
"
DEPEND="${RDEPEND}"
BDEPEND="
gtk-doc? ( dev-util/gtk-doc )
test? (
$(python_gen_any_dep 'dev-python/python-dbusmock[${PYTHON_USEDEP}]')
dev-util/umockdev
)
"
RESTRICT="!test? ( test )"
python_check_deps() {
use test || return 0
python_has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]"
}
src_configure() {
local emesonargs=(
$(meson_use gtk-doc gtk_doc)
$(meson_use test tests)
)
meson_src_configure
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
elog "You need to run systemd and enable the service:"
elog "# systemctl enable switcheroo-control"
fi
}
|
GitWeb
