blob: 0fc8e282259981948efc8f9fc28c6fb0a6fdc2d1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit kernel-build
MY_P=linux-${PV}
# https://git.archlinux.org/svntogit/packages.git/log/trunk/config?h=packages/linux
AMD64_CONFIG_VER=5.5.5-arch1
AMD64_CONFIG_HASH=e4d4ca36741d228042185e2a9047cd88fb5b4169
# https://git.archlinux32.org/packages/log/core/linux/config.i686
I686_CONFIG_VER=5.5.6-arch1
I686_CONFIG_HASH=7d53d8a42f68648bce5b002aaf8c2b14e6298275
DESCRIPTION="Linux kernel built from vanilla upstream sources"
HOMEPAGE="https://www.kernel.org/"
SRC_URI+=" https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
amd64? (
https://git.archlinux.org/svntogit/packages.git/plain/trunk/config?h=packages/linux&id=${AMD64_CONFIG_HASH}
-> linux-${AMD64_CONFIG_VER}.amd64.config
)
x86? (
https://git.archlinux32.org/packages/plain/core/linux/config.i686?id=${I686_CONFIG_HASH}
-> linux-${I686_CONFIG_VER}.i686.config
)"
S=${WORKDIR}/${MY_P}
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
RDEPEND="
!sys-kernel/vanilla-kernel-bin:${SLOT}"
src_prepare() {
default
# prepare the default config
case ${ARCH} in
amd64)
cp "${DISTDIR}"/linux-${AMD64_CONFIG_VER}.amd64.config .config || die
;;
x86)
cp "${DISTDIR}"/linux-${I686_CONFIG_VER}.i686.config .config || die
;;
*)
die "Unsupported arch ${ARCH}"
;;
esac
local config_tweaks=(
# shove arch under the carpet!
-e 's:^CONFIG_DEFAULT_HOSTNAME=:&"gentoo":'
# we do support x32
-e '/CONFIG_X86_X32/s:.*:CONFIG_X86_X32=y:'
# disable signatures
-e '/CONFIG_MODULE_SIG/d'
-e '/CONFIG_SECURITY_LOCKDOWN/d'
# disable compression to allow stripping
-e '/CONFIG_MODULE_COMPRESS/d'
# disable gcc plugins to unbreak distcc
-e '/CONFIG_GCC_PLUGIN_STRUCTLEAK/d'
)
sed -i "${config_tweaks[@]}" .config || die
}
|
GitWeb
