blob: 7713ea4da2c54429fc6ccd72430a795403f18105 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit libtool
DESCRIPTION="Apps for querying the sg SCSI interface"
HOMEPAGE="https://sg.danny.cz/sg/"
#SRC_URI="https://github.com/hreinecke/sg3_utils/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SRC_URI="https://sg.danny.cz/sg/p/${P}.tar.xz"
LICENSE="GPL-2"
SLOT="0/${PV}"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="static-libs"
RDEPEND="!sys-apps/rescan-scsi-bus"
PATCHES=(
# Bug #828897
"${FILESDIR}"/${PN}-1.47-musl.patch
)
src_prepare() {
default
elibtoolize
}
src_configure() {
econf $(use_enable static-libs static)
}
src_install() {
default
dodoc COVERAGE doc/README examples/*.txt
newdoc scripts/README README.scripts
find "${ED}" -type f -name "*.la" -delete || die
# Better fix for bug 231089; some packages look for sgutils2
local path lib
path="/usr/$(get_libdir)"
for lib in "${ED}/"${path}/libsgutils2{,-${PV}}.*; do
lib=${lib##*/}
dosym "${lib}" "${path}/${lib/libsgutils2/libsgutils}"
done
}
|
GitWeb
