blob: 54b9ff482fabc4728b9422bb0fcc3d75cde93f0d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools toolchain-funcs
DESCRIPTION="An extremely configurable ftp client"
HOMEPAGE="https://www.ncftp.com/"
SRC_URI="
https://ftp.mirrorservice.org/sites/ftp.${PN}.com/${PN}/${P}-src.tar.xz
"
LICENSE="Clarified-Artistic"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
IUSE="pch"
DEPEND="
sys-libs/ncurses:=
"
RDEPEND="
${DEPEND}
"
BDEPEND="
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}"/${PN}-3.2.6-fno-common.patch
"${FILESDIR}"/${PN}-3.2.6-fix-clang.patch # 875458
)
src_prepare() {
default
sed -i -e '/^AR=/d' autoconf_local/aclocal.m4 || die
# 727774
sed -i -e 's/STRIP=".*"/STRIP=":"/' autoconf_local/aclocal.m4 || die
AT_M4DIR=autoconf_local/ eautoreconf
}
src_configure() {
tc-export AR CC
LC_ALL="C" \
LIBS="$( $(tc-getPKG_CONFIG) --libs ncurses)" \
econf \
$(use_enable pch precomp) \
--disable-ccdv \
--disable-universal
}
src_install() {
default
dodoc README.txt doc/*.txt
docinto html
dodoc doc/html/*.html
}
|
GitWeb
