blob: e4c232ea119073ff82e527ad61947baf5a9674f5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic toolchain-funcs
DESCRIPTION="A Tool for network monitoring and data acquisition"
HOMEPAGE="
https://www.tcpdump.org/
https://github.com/the-tcpdump-group/tcpdump
"
SRC_URI="
https://www.tcpdump.org/release/${P}.tar.gz
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux"
IUSE="+drop-root libressl smi ssl samba suid test"
RESTRICT="!test? ( test )"
RDEPEND="
drop-root? (
acct-group/pcap
acct-user/pcap
sys-libs/libcap-ng
)
net-libs/libpcap
smi? ( net-libs/libsmi )
ssl? (
!libressl? ( >=dev-libs/openssl-0.9.6m:0= )
libressl? ( dev-libs/libressl:= )
)
suid? (
acct-group/pcap
acct-user/pcap
)
"
DEPEND="
${RDEPEND}
drop-root? ( virtual/pkgconfig )
test? (
>=net-libs/libpcap-1.9.1
dev-lang/perl
app-arch/sharutils
)
"
src_configure() {
if use drop-root; then
append-cppflags -DHAVE_CAP_NG_H
export LIBS=$( $(tc-getPKG_CONFIG) --libs libcap-ng )
fi
econf \
$(use_enable samba smb) \
$(use_with drop-root chroot '') \
$(use_with smi) \
$(use_with ssl crypto "${ESYSROOT}/usr") \
$(usex drop-root "--with-user=pcap" "")
}
src_test() {
if [[ ${EUID} -ne 0 ]] || ! use drop-root; then
emake check
else
ewarn "If you want to run the test suite, make sure you either"
ewarn "set FEATURES=userpriv or set USE=-drop-root"
fi
}
src_install() {
dosbin tcpdump
doman tcpdump.1
dodoc *.awk
dodoc CHANGES CREDITS README.md
if use suid; then
fowners root:pcap /usr/sbin/tcpdump
fperms 4110 /usr/sbin/tcpdump
fi
}
pkg_postinst() {
use suid && elog "To let normal users run tcpdump add them to the pcap group."
}
|
GitWeb