blob: ee4be14591e4dc4e71a5d2cf438e857bdcba1a9b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Copyright 2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools flag-o-matic
EGIT_COMMIT="7563a96b8f8e86b7a5fd1ce783388adf29bf4cf9"
DESCRIPTION="VoIP library for Telegram clients"
HOMEPAGE="https://github.com/telegramdesktop/libtgvoip"
SRC_URI="https://github.com/telegramdesktop/libtgvoip/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
LICENSE="Unlicense"
SLOT="0"
KEYWORDS="~amd64 ~ppc64"
IUSE="+dsp libressl"
DEPEND="
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
media-libs/opus:=
media-libs/alsa-lib
|| ( media-sound/pulseaudio media-sound/apulse[sdk] )
"
RDEPEND="${DEPEND}"
BDEPEND="virtual/pkgconfig"
S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
src_prepare() {
default
sed -i 's/-std=gnu++0x/-std=gnu++17/' Makefile.am || die
# https://bugs.gentoo.org/717210
echo 'libtgvoip_la_LIBTOOLFLAGS = --tag=CXX' >> Makefile.am || die
eautoreconf
}
src_configure() {
local myconf=(
--disable-static
--with-alsa
--with-pulse
$(use_enable dsp)
)
use dsp && append-cxxflags '-DTGVOIP_USE_DESKTOP_DSP_BUNDLED'
econf "${myconf[@]}"
}
src_install() {
default
find "${D}" -name '*.la' -delete || die
}
|
GitWeb
