blob: 8ab68490c7d7b7f7cea78b170b10e819bccc61ff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit desktop toolchain-funcs
DESCRIPTION="Image viewers for the framebuffer console (fbi) and X11 (ida)"
HOMEPAGE="https://www.kraxel.org/blog/linux/fbida/"
SRC_URI="
https://www.kraxel.org/releases/${PN}/${P}.tar.gz
mirror://gentoo/ida.png.bz2
"
LICENSE="GPL-2 IJG"
SLOT="0"
KEYWORDS="~alpha ~amd64 arm ~hppa ppc ppc64 ~sparc x86"
IUSE="curl fbcon ghostscript +gif lirc +png scanner +tiff X +webp"
REQUIRED_USE="
ghostscript? ( tiff )
"
CDEPEND="
!media-gfx/fbi
>=media-libs/fontconfig-2.2
>=media-libs/freetype-2.0
app-text/poppler
media-libs/libepoxy
media-libs/libexif
virtual/jpeg:*
virtual/ttf-fonts
x11-libs/cairo[opengl]
curl? ( net-misc/curl )
fbcon? (
app-text/poppler[cairo]
media-libs/mesa[X(+),gbm]
x11-libs/libdrm
x11-libs/pixman
)
gif? ( media-libs/giflib:= )
lirc? ( app-misc/lirc )
png? ( media-libs/libpng:* )
scanner? ( media-gfx/sane-backends )
tiff? ( media-libs/tiff:* )
webp? ( media-libs/libwebp )
X? (
>=x11-libs/motif-2.3:0[xft]
x11-libs/libX11
x11-libs/libXpm
x11-libs/libXt
)
"
DEPEND="
${CDEPEND}
X? ( x11-base/xorg-proto )
"
RDEPEND="
${CDEPEND}
ghostscript? (
app-text/ghostscript-gpl
)
"
PATCHES=(
"${FILESDIR}"/ida-desktop.patch
"${FILESDIR}"/${PN}-2.10-giflib-4.2.patch
"${FILESDIR}"/${PN}-2.14-Autoconf.patch
"${FILESDIR}"/${PN}-2.14-fno-common.patch
"${FILESDIR}"/${PN}-2.14-cpp.patch
)
src_configure() {
tc-export CC CPP
# Let autoconf do its job and then fix things to build fbida
# according to our specifications
emake Make.config
gentoo_fbida() {
local useflag=${1}
local config=${2}
local option="no"
use ${useflag} && option="yes"
sed -i \
-e "s|HAVE_${config}.*|HAVE_${config} := ${option}|" \
"${S}/Make.config" || die
}
gentoo_fbida X MOTIF
gentoo_fbida curl LIBCURL
gentoo_fbida fbcon LINUX_FB_H
gentoo_fbida gif LIBUNGIF
gentoo_fbida lirc LIBLIRC
gentoo_fbida ghostscript LIBTIFF
gentoo_fbida png LIBPNG
gentoo_fbida scanner LIBSANE
gentoo_fbida tiff LIBTIFF
gentoo_fbida webp LIBWEBP
}
src_compile() {
emake verbose=yes
}
src_install() {
emake \
DESTDIR="${ED}" \
STRIP="" \
prefix=/usr \
install
dodoc README
if use fbcon && ! use ghostscript; then
rm \
"${ED}"/usr/bin/fbgs \
"${ED}"/usr/share/man/man1/fbgs.1 \
|| die
fi
if use X ; then
doicon "${WORKDIR}"/ida.png
domenu desktop/ida.desktop
fi
}
|
GitWeb