blob: 70a541a281a1eec8c12526442c975b85439dad21 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
GENQMAIL_PV=20200817
QMAIL_SPP_PV=0.42
QMAIL_TLS_PV=20190114
QMAIL_TLS_F=${PN}-1.05-tls-smtpauth-${QMAIL_TLS_PV}.patch
QMAIL_TLS_CVE=vu555316.patch
QMAIL_BIGTODO_F=big-todo.103.patch
QMAIL_LARGE_DNS='qmail-103.patch'
QMAIL_SMTPUTF8='qmail-smtputf8.patch'
inherit qmail
DESCRIPTION="qmail -- a secure, reliable, efficient, simple message transfer agent"
HOMEPAGE="
http://netqmail.org
https://cr.yp.to/qmail.html
http://qmail.org
"
SRC_URI="http://qmail.org/${P}.tar.gz
https://github.com/DerDakon/genqmail/releases/download/genqmail-${GENQMAIL_PV}/${GENQMAIL_F}
https://www.ckdhr.com/ckd/${QMAIL_LARGE_DNS}
!vanilla? (
highvolume? ( http://qmail.org/${QMAIL_BIGTODO_F} )
qmail-spp? ( https://downloads.sourceforge.net/qmail-spp/${QMAIL_SPP_F} )
ssl? (
https://mirror.alexh.name/qmail/netqmail/${QMAIL_TLS_F}
http://inoa.net/qmail-tls/${QMAIL_TLS_CVE}
https://arnt.gulbrandsen.priv.no/qmail/qmail-smtputf8.patch
)
)
"
LICENSE="public-domain"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~hppa ~mips ppc64 ~s390 sparc x86"
IUSE="gencertdaily highvolume pop3 qmail-spp ssl vanilla"
REQUIRED_USE="vanilla? ( !ssl !qmail-spp !highvolume )"
RESTRICT="test"
DEPEND="
acct-group/nofiles
acct-group/qmail
acct-user/alias
acct-user/qmaild
acct-user/qmaill
acct-user/qmailp
acct-user/qmailq
acct-user/qmailr
acct-user/qmails
net-dns/libidn2
net-mail/queue-repair
sys-apps/gentoo-functions
sys-apps/groff
ssl? ( >=dev-libs/openssl-1.1:0= )
"
RDEPEND="${DEPEND}
sys-apps/ucspi-tcp
virtual/checkpassword
virtual/daemontools
!mail-mta/courier
!mail-mta/esmtp
!mail-mta/exim
!mail-mta/mini-qmail
!mail-mta/msmtp[mta]
!mail-mta/nullmailer
!mail-mta/opensmtpd
!mail-mta/postfix
!mail-mta/qmail-ldap
!mail-mta/sendmail
!mail-mta/ssmtp[mta]
"
src_unpack() {
genqmail_src_unpack
use qmail-spp && qmail_spp_src_unpack
unpack ${P}.tar.gz
}
PATCHES=(
"${FILESDIR}/${PV}-exit.patch"
"${FILESDIR}/${PV}-readwrite.patch"
"${DISTDIR}/${QMAIL_LARGE_DNS}"
"${FILESDIR}/${PV}-fbsd-utmpx.patch"
"${FILESDIR}/${P}-ipme-multiple.patch"
"${FILESDIR}/${P}-any-to-cname.patch"
"${FILESDIR}/${P}-CVE-2005-1513.patch"
"${FILESDIR}/${P}-CVE-2005-1514.patch"
"${FILESDIR}/${P}-CVE-2005-1515.patch"
"${FILESDIR}/${P}-overflows.patch"
)
src_prepare() {
if ! use vanilla; then
if use ssl; then
# This patch contains relative paths and needs to be cleaned up.
sed 's~^--- \.\./\.\./~--- ~g' \
< "${DISTDIR}"/${QMAIL_TLS_F} \
> "${T}"/${QMAIL_TLS_F} || die
PATCHES+=( "${T}/${QMAIL_TLS_F}"
"${DISTDIR}/${QMAIL_TLS_CVE}"
"${FILESDIR}/qmail-smtputf8.patch"
"${FILESDIR}/qmail-smtputf8-crlf-fix.patch"
)
fi
if use highvolume; then
PATCHES+=( "${DISTDIR}/${QMAIL_BIGTODO_F}" )
fi
if use qmail-spp; then
if use ssl; then
SPP_PATCH="${QMAIL_SPP_S}/qmail-spp-smtpauth-tls-20060105.diff"
else
SPP_PATCH="${QMAIL_SPP_S}/netqmail-spp.diff"
fi
# make the patch work with "-p1"
sed -e 's#^--- \([Mq]\)#--- a/\1#' -e 's#^+++ \([Mq]\)#+++ b/\1#' -i ${SPP_PATCH} || die
PATCHES+=( "${SPP_PATCH}" )
fi
fi
default
qmail_src_postunpack
# Fix bug #33818 but for netqmail (Bug 137015)
einfo "Disabled CRAM_MD5 support"
sed -e 's,^#define CRAM_MD5$,/*&*/,' -i "${S}"/qmail-smtpd.c || die
ht_fix_file Makefile*
}
src_compile() {
qmail_src_compile
use qmail-spp && qmail_spp_src_compile
}
src_install() {
qmail_src_install
}
pkg_postinst() {
qmail_queue_setup
qmail_rootmail_fixup
qmail_tcprules_build
qmail_config_notice
qmail_supervise_config_notice
elog
elog "If you are looking for documentation, check those links:"
elog "https://wiki.gentoo.org/wiki/Virtual_mail_hosting_with_qmail"
elog " -- qmail/vpopmail Virtual Mail Hosting System Guide"
elog "http://www.lifewithqmail.com/"
elog " -- Life with qmail"
elog
}
pkg_config() {
# avoid some weird locale problems
export LC_ALL=C
qmail_config_fast
qmail_tcprules_config
qmail_tcprules_build
use ssl && qmail_ssl_generate
}
|
GitWeb