blob: a1239ecaa187ff2064feb2073692ebd94fcb7b31 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit desktop toolchain-funcs
DESCRIPTION="Simulated obstacle course for automobiles"
HOMEPAGE="http://www.stolk.org/stormbaancoureur/"
SRC_URI="http://www.stolk.org/stormbaancoureur/download/${P}.tar.gz"
S="${WORKDIR}/${P}/src-stormbaancoureur"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
DEPEND="
>=dev-games/ode-0.8[-double-precision]
media-libs/alsa-lib
media-libs/freeglut
>=media-libs/plib-1.8.4
virtual/glu
virtual/opengl"
RDEPEND="${DEPEND}"
PATCHES=(
"${FILESDIR}"/${P}-gentoo.patch
"${FILESDIR}"/${P}-clang.patch
)
src_prepare() {
default
sed -ie "s:GENTOODIR:/usr/share/${PN}:" main.cxx || die
}
src_compile() {
tc-export CXX
emake LIBDIRNAME=$(get_libdir)
}
src_install() {
dobin ${PN}
insinto /usr/share/${PN}
doins -r images/ models/ sounds/ shaders/
dodoc JOYSTICKS README TODO
make_desktop_entry ${PN} "Stormbaan Coureur"
}
|
GitWeb
