blob: 4271e2406593349e2d1b15d1ae87f23c43605e08 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Copyright 2021-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit distutils-r1
DESCRIPTION="Quickly rewrite git repository history (filter-branch replacement)"
HOMEPAGE="https://github.com/newren/git-filter-repo/"
SRC_URI="https://github.com/newren/git-filter-repo/releases/download/v${PV}/${P}.tar.xz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="
${PYTHON_DEPS}
>=dev-vcs/git-$(ver_cut 1-2)
"
BDEPEND+="
dev-python/setuptools-scm[${PYTHON_USEDEP}]
"
S="${S}/release"
# the git-archive tarball does not have version info; setuptools-scm
# requires a valid source of version info, this one is for distros
export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
python_test() {
cd .. || die
bash t/run_tests || die
}
python_install_all() {
distutils-r1_python_install_all
# Just like git itself there is a manpage in troff + html formats.
# Unlike git itself, we cannot install the html one, because the
# `git --html-path` has the ${PV} of git in it. So just install
# the troff copy.
doman "${WORKDIR}"/${P}/Documentation/man1/git-filter-repo.1
# Points to dead symlink
rm "${ED}"/usr/share/doc/${PF}/README.md || die
rmdir "${ED}"/usr/share/doc/${PF} || die
dodoc "${WORKDIR}"/${P}/README.md
}
|
GitWeb
