blob: 2e564e60bf9c2d4a8fcb8929f44a859fd63b380d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 2012-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit multilib multilib-minimal
if [[ ${PV} == "9999" ]] ; then
inherit autotools git-r3
EGIT_REPO_URI="https://git.sr.ht/~kaniini/pkgconf"
else
SRC_URI="http://distfiles.dereferenced.org/${PN}/${P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
fi
DESCRIPTION="pkg-config compatible replacement with no dependencies other than ANSI C89"
HOMEPAGE="https://git.sr.ht/~kaniini/pkgconf"
LICENSE="ISC"
SLOT="0/3"
IUSE="test"
# tests require 'kyua'
RESTRICT="!test? ( test )"
BDEPEND="
test? (
dev-libs/atf
dev-util/kyua
)
"
RDEPEND="
!dev-util/pkgconfig
"
MULTILIB_CHOST_TOOLS=(
/usr/bin/pkgconf$(get_exeext)
)
src_prepare() {
default
[[ ${PV} == "9999" ]] && eautoreconf
MULTILIB_CHOST_TOOLS+=(
/usr/bin/pkg-config$(get_exeext)
)
}
multilib_src_configure() {
local ECONF_SOURCE="${S}"
local args=(
--disable-static
--with-system-includedir="${EPREFIX}/usr/include"
--with-system-libdir="${EPREFIX}/$(get_libdir):${EPREFIX}/usr/$(get_libdir)"
)
econf "${args[@]}"
}
multilib_src_test() {
unset PKG_CONFIG_LIBDIR PKG_CONFIG_PATH
default
}
multilib_src_install() {
default
dosym pkgconf$(get_exeext) /usr/bin/pkg-config$(get_exeext)
dosym pkgconf.1 /usr/share/man/man1/pkg-config.1
}
multilib_src_install_all() {
einstalldocs
find "${ED}" -type f -name '*.la' -delete || die
}
|
GitWeb
