dev-python/django-tagging/django-tagging-0.5.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{9..10} )

inherit distutils-r1

DESCRIPTION="Generic tagging application for Django"
HOMEPAGE="https://pypi.org/project/django-tagging/
	https://github.com/Fantomas42/django-tagging"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"
RESTRICT="!test? ( test )"

# wants smart_text which was removed from django-4.0 and up
RDEPEND=">=dev-python/django-1.0[${PYTHON_USEDEP}]
	<dev-python/django-4[${PYTHON_USEDEP}]"
BDEPEND="
	test? (
		$(python_gen_impl_dep sqlite)
	)"

distutils_enable_sphinx docs

python_test() {
	local -x DJANGO_SETTINGS_MODULE=tagging.tests.settings
	local -x PYTHONPATH=.
	django-admin test -v 2 tagging || die "Tests failed with ${EPYTHON}"
}