blob: 0f6aaa574f938aee0ed9348f572934f18156801f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
EAPI=7
# DO NOT ADD pypy to PYTHON_COMPAT
# pypy bundles a modified version of cffi. Use python_gen_cond_dep instead.
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1 toolchain-funcs
DESCRIPTION="Foreign Function Interface for Python calling C code"
HOMEPAGE="https://cffi.readthedocs.io/ https://pypi.org/project/cffi/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0/${PV}"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
DEPEND="dev-libs/libffi:="
RDEPEND="${DEPEND}
dev-python/pycparser[${PYTHON_USEDEP}]"
BDEPEND="${RDEPEND}
virtual/pkgconfig"
distutils_enable_sphinx doc/source
distutils_enable_tests pytest
PATCHES=(
"${FILESDIR}"/cffi-1.14.0-darwin-no-brew.patch
)
src_prepare() {
if [[ ${CHOST} == *darwin* ]] ; then
# Don't obsessively try to find libffi
sed -i -e "s/.*\-iwithsysroot\/usr\/include\/ffi.*/\tpass/" setup.py || die
fi
distutils-r1_src_prepare
}
src_configure() {
tc-export PKG_CONFIG
}
python_test() {
"${EPYTHON}" -c "import _cffi_backend as backend" || die
epytest \
--ignore testing/test_zintegration.py \
--ignore testing/embedding \
c/ testing/
}
|
GitWeb
