blob: 49e74c6ddbfa1dad2c9fa9771670cc297f35aa0f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
# note the patch below
DISTUTILS_USE_SETUPTOOLS=no
PYTHON_COMPAT=( python2_7 python3_{6,7,8} pypy3 )
inherit distutils-r1
DESCRIPTION="Module for determining appropriate platform-specific dirs"
HOMEPAGE="https://github.com/ActiveState/appdirs"
SRC_URI="https://github.com/ActiveState/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 m68k ~mips ppc ppc64 s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
PATCHES=( "${FILESDIR}"/${PN}-1.4.3-distutils.patch )
python_test() {
"${PYTHON}" test/test_api.py -v || die "Tests fail with ${EPYTHON}"
}
[[ ${PV} == 1.4.3 ]] || die "Please remove pkg_preinst from the ebuild"
pkg_preinst() {
_remove_egg_info() {
local pyver="$("${PYTHON}" -c 'import sys; print(sys.version[:3])')"
local egginfo="${ROOT}$(python_get_sitedir)/${P}-py${pyver}.egg-info"
if [[ -d ${egginfo} ]]; then
einfo "Removing ${egginfo}"
rm -r "${egginfo}" || die
fi
}
python_foreach_impl _remove_egg_info
}
|
GitWeb
