blob: 396f01c7ef9a760d7e80e9c76b6e45ac6b6a0e9e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
DESCRIPTION="RPC/Serialization system with capabilities support"
HOMEPAGE="https://capnproto.org"
SRC_URI="https://github.com/sandstorm-io/capnproto/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0/080"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
IUSE="+ssl static-libs test zlib"
RESTRICT="!test? ( test )"
RDEPEND="
ssl? (
dev-libs/openssl:0=
)
zlib? ( sys-libs/zlib:0= )
"
DEPEND="${RDEPEND} test? ( dev-cpp/gtest )"
S=${WORKDIR}/${P}/c++
src_prepare() {
sed -e 's/ldconfig/true/' -i Makefile.am || die
sed -e 's#gtest/lib/libgtest.la gtest/lib/libgtest_main.la#-lgtest -lgtest_main#' -i Makefile.am || die
default
eautoreconf
}
src_configure() {
econf \
$(use_enable static-libs static) \
$(use_with ssl openssl) \
$(use_with zlib)
}
src_install() {
default
find "${ED}" -name '*.la' -delete
}
|
GitWeb
