blob: c32743ed8dbadc3d37fb7f449c70237db0c5d86d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake flag-o-matic optfeature toolchain-funcs
DESCRIPTION="Tail with multiple windows"
HOMEPAGE="http://www.vanheusden.com/multitail/ https://github.com/folkertvanheusden/multitail/"
SRC_URI="https://github.com/folkertvanheusden/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ia64 ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="debug examples unicode"
RDEPEND="sys-libs/ncurses:=[unicode(+)?]"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PN}-7.0.0-gentoo.patch
"${FILESDIR}"/${PN}-7.0.0-fix-clang16-build.patch
"${FILESDIR}"/${PN}-7.0.0-fix-lto-type-mismatch.patch
)
src_prepare() {
cmake_src_prepare
# cmake looks for licence.txt to install it, which does not exist in the package
cp LICENSE license.txt || die
}
src_configure() {
local mycmakeargs=(
-DUTF8_SUPPORT=$(usex unicode)
)
CMAKE_BUILD_TYPE=$(usex debug Debug)
cmake_src_configure
}
src_install() {
cmake_src_install
insinto /etc
doins multitail.conf
rm -rf "${ED}"/usr/{ect,etc} || die
rm -rf "${ED}"/usr/share/doc/multitail-VERSION=6.4.3 || die
DOCS=( readme.txt thanks.txt )
HTML_DOCS=( manual.html )
einstalldocs
if use examples; then
docinto examples
dodoc conversion-scripts/colors-example.{pl,sh} conversion-scripts/convert-{geoip,simple}.pl
fi
}
pkg_postinst() {
optfeature "send a buffer to the X clipboard" x11-misc/xclip
}
|
GitWeb
