blob: 6d65c4ee002b9a8d8cee8e5e8d8f6818dbb1208a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic toolchain-funcs
DESCRIPTION="Debian Almquist Shell"
HOMEPAGE="http://gondor.apana.org.au/~herbert/dash/"
SRC_URI="http://gondor.apana.org.au/~herbert/dash/files/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
IUSE="libedit static"
BDEPEND="virtual/pkgconfig"
RDEPEND="!static? ( libedit? ( dev-libs/libedit ) )"
DEPEND="
${RDEPEND}
libedit? ( static? ( dev-libs/libedit[static-libs] ) )
"
src_prepare() {
default
# Fix the invalid sort
sed -i -e 's/LC_COLLATE=C/LC_ALL=C/g' src/mkbuiltins || die
# Use pkg-config for libedit linkage
sed -i \
-e "/LIBS/s:-ledit:\`$(tc-getPKG_CONFIG) --libs libedit $(usex static --static '')\`:" \
configure || die
}
src_configure() {
if [[ ${CHOST} == *-solaris* ]] ; then
# don't redefine stat, open, dirent, etc. on Solaris
export ac_cv_func_stat64=yes
export ac_cv_func_open64=yes
# if your headers strictly adhere to POSIX, you'll need this too
[[ ${CHOST##*solaris2.} -le 10 ]] && append-cppflags -DNAME_MAX=255
fi
if [[ ${CHOST} == powerpc-*-darwin* ]] ; then
sed -i -e 's/= stpncpy(s, \([^,]\+\), \([0-9]\+\))/+= snprintf(s, \2, "%s", \1)/' \
src/jobs.c || die
fi
use static && append-ldflags -static
append-cppflags -DJOBS=$(usex libedit 1 0)
# Do not pass --enable-glob due to #443552.
local myeconfargs=(
CC_FOR_BUILD="$(tc-getBUILD_CC)"
--bindir="${EPREFIX}"/bin
--enable-fnmatch
$(use_with libedit)
)
econf "${myeconfargs[@]}"
}
|
GitWeb
