blob: 6fa10f6c45dd4d787b5e1024cee568c0fa7c31a4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit desktop qmake-utils xdg
MY_PV="${PV/_/}"
DESCRIPTION="Free cross-platform LaTeX editor (fork from texmakerX)"
HOMEPAGE="https://www.texstudio.org https://github.com/texstudio-org/texstudio"
SRC_URI="https://github.com/texstudio-org/texstudio/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-${MY_PV}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="video"
DEPEND="
app-text/hunspell:=
app-text/poppler:=[qt5]
>=dev-libs/quazip-1.0:0=[qt5(+)]
dev-qt/designer:5
dev-qt/qtcore:5
dev-qt/qtconcurrent:5
dev-qt/qtdeclarative:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtprintsupport:5
dev-qt/qtsingleapplication[qt5(+),X]
dev-qt/qtsvg:5
dev-qt/qttest:5
dev-qt/qtwidgets:5
dev-qt/qtxml:5
sys-libs/zlib
x11-libs/libX11
x11-libs/libXext
video? ( >=media-libs/phonon-4.11.0 )
"
RDEPEND="
${DEPEND}
app-text/ghostscript-gpl
app-text/psutils
media-libs/netpbm
virtual/latex-base
"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}/${PN}-3.0.5-quazip1.patch" # TODO: upstream
)
src_prepare() {
# TODO: find hunspell quazip utilities/poppler-data qtsingleapplication -delete || die
rm -r src/quazip || die
if use video; then
sed "/^PHONON/s:$:true:g" -i ${PN}.pro || die
fi
sed -e "/qtsingleapplication.pri/s/.*/CONFIG += qtsingleapplication/" \
-i ${PN}.pro || die
default
}
src_configure() {
eqmake5 USE_SYSTEM_HUNSPELL=1 USE_SYSTEM_QUAZIP=1 NO_TESTS=false
}
src_install() {
local i
for i in 16x16 22x22 32x32 48x48 64x64 128x128; do
newicon -s ${i} utilities/${PN}${i}.png ${PN}.png
done
emake DESTDIR="${D}" INSTALL_ROOT="${ED}" install
# We don't install licences per package
rm "${ED}"/usr/share/texstudio/COPYING || die
}
|
GitWeb