blob: 065678dfa3337bdbc757c86bdf3ea98943f5040c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools desktop udev
DESCRIPTION="Unofficial tool for controlling the Razer Copperhead mouse"
HOMEPAGE="https://razertool.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P/-/_}.orig.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gtk"
RDEPEND="dev-libs/glib:2
virtual/libusb:0
virtual/udev
gtk? (
dev-libs/atk
>=gnome-base/librsvg-2.0
>=x11-libs/cairo-1.0.0
x11-libs/gdk-pixbuf
>=x11-libs/gtk+-2.8.0:2
)"
DEPEND="${RDEPEND}
virtual/pkgconfig"
DOCS=( AUTHORS ChangeLog NEWS README )
PATCHES=( "${FILESDIR}"/${P}-configure.patch
"${FILESDIR}"/${P}-rules.patch )
src_prepare() {
default
eautoreconf
}
src_configure() {
econf $(use_enable gtk)
}
src_install() {
default
udev_newrules razertool.rules.example 90-razertool.rules
# Icon and desktop entry
if use gtk; then
dosym ../razertool/pixmaps/razertool-icon.png /usr/share/pixmaps/razertool-icon.png
make_desktop_entry "razertool-gtk" "RazerTool" ${PN}-icon "GTK;Settings;HardwareSettings"
fi
}
pkg_postinst() {
udev_reload
elog "Razer Copperhead mice need firmware version 6.20 or higher"
elog "to work properly. Running ${PN} on mice with older firmwares"
elog "might lead to random USB-disconnects."
elog "To run as non-root, add yourself to the usb group:"
elog " gpasswd -a <user> usb"
elog "or adapt permissions/owner/group in:"
elog " /etc/udev/rules.d/90-razertool.rules"
elog "Then unplug and plug in the mouse."
}
pkg_postrm() {
udev_reload
}
|
GitWeb
