blob: 894d05fefaa4b14bf08d34a89b38abb2d1d16688 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Copyright 2022-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ALTERNATIVES=(
"reference:>=app-arch/bzip2-1.0.8-r4"
"lbzip2:app-arch/lbzip2[-symlink(-)]"
"pbzip2:app-arch/pbzip2[-symlink(-)]"
)
inherit app-alternatives
DESCRIPTION="bzip2 symlink"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~sparc64-solaris ~x64-solaris"
IUSE="split-usr"
RDEPEND="
!<app-arch/bzip2-1.0.8-r4
!app-arch/lbzip2[symlink(-)]
!app-arch/pbzip2[symlink(-)]
"
src_install() {
local alt=$(get_alternative)
local usr_prefix=
use split-usr && usr_prefix=../usr/bin/
case ${alt} in
reference)
dosym bzip2-reference /bin/bzip2
alt=bzip2-reference
;;
*)
dosym "${usr_prefix}${alt}" /bin/bzip2
;;
esac
dosym bzip2 /bin/bunzip2
dosym bzip2 /bin/bzcat
newman - bzip2.1 <<<".so ${alt}.1"
newman - bunzip2.1 <<<".so bzip2.1"
newman - bzcat.1 <<<".so bzip2.1"
}
|
GitWeb
