app-admin/logsurfer+/logsurfer+-1.8-r5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

MY_P="${P/+/}"

inherit toolchain-funcs

DESCRIPTION="Real Time Log Monitoring and Alerting"
HOMEPAGE="https://crypt.gen.nz/logsurfer/"
SRC_URI="mirror://sourceforge/logsurfer/${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"

LICENSE="freedist GPL-2+"
SLOT="0"
KEYWORDS="amd64 x86"
RESTRICT="bindist" #444330

RDEPEND="
	acct-group/logsurfer
	acct-user/logsurfer
"

PATCHES=( "${FILESDIR}/${P}-fix-declaration-of-check_context_linelimit.patch" )

src_configure() {
	local myeconfargs=(
		--with-etcdir=/etc
	)

	econf "${myeconfargs[@]}"
}

src_compile() {
	tc-export CC
	default
}

src_install() {
	dobin src/logsurfer
	doman man/logsurfer.1 man/logsurfer.conf.4

	newinitd "${FILESDIR}"/logsurfer-1.8.initd-r1 logsurfer
	newconfd "${FILESDIR}"/logsurfer.confd logsurfer

	einstalldocs
}