2 files changed, 59 insertions, 0 deletions
diff --git a/sci-libs/volk/Manifest b/sci-libs/volk/Manifest
index 34a3676eaad0..9f69fdc2758b 100644
--- a/sci-libs/volk/Manifest
+++ b/sci-libs/volk/Manifest
@@ -1 +1,2 @@
 DIST volk-3.1.0.tar.xz 420088 BLAKE2B 709c3561675b0f71a1400d7b9332aa18c6d2ae848c993914cb40484890f631bde48da12ab9756be38cca9fbb20d0d851cb40ff5bfe3722ff72cd0b4daff1b11d SHA512 0c39c06e5121782461c0ea2c84402c84f9609a2a09ce7218e976472081d09531746ea1cde767f329a69d72d51cf5715bf7f2df1b26a8d8ddd1694e8239f5ff21
+DIST volk-3.1.2.tar.xz 381388 BLAKE2B c67049921cf0817ff263ae3b0b14b2939e69e461fa731b47f0f923ebe730e67a8715f20738b1991fc9956abd12eccfa50a421460feef12e7678d26a25d73acce SHA512 6fd99b037e2c2481f4886a70021403a8641567a0c0280496194da7ef1b8cf7dbecf91d5bfc1b1c3449788de360206bae5036d796a01bbec211ccf9ccbbc357ee
diff --git a/sci-libs/volk/volk-3.1.2.ebuild b/sci-libs/volk/volk-3.1.2.ebuild
new file mode 100644
index 000000000000..0a400d90ff06
--- /dev/null
+++ b/sci-libs/volk/volk-3.1.2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+
+#https://github.com/gnuradio/volk/issues/383
+CMAKE_BUILD_TYPE="None"
+inherit cmake python-single-r1
+
+DESCRIPTION="vector optimized library of kernels"
+HOMEPAGE="http://libvolk.org"
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/gnuradio/volk.git"
+else
+	SRC_URI="https://github.com/gnuradio/volk/releases/download/v${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~riscv ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0/$(ver_cut 1-2)"
+IUSE="orc test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RDEPEND="${PYTHON_DEPS}
+	orc? ( dev-lang/orc )"
+DEPEND="${RDEPEND}
+	$(python_gen_cond_dep 'dev-python/mako[${PYTHON_USEDEP}]')"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_ORC=$(usex orc)
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DENABLE_TESTING="$(usex test)"
+		-DENABLE_PROFILING=OFF
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# Remove stray python files generated by the build system
+	find "${ED}" -name '*.pyc' -exec rm -f {} \; || die
+	find "${ED}" -name '*.pyo' -exec rm -f {} \; || die
+	python_optimize
+}
+
+src_test() {
+	local myctestargs=(
+		-E "(check_lgpl)"
+	)
+	cmake_src_test
+}