1 files changed, 45 insertions, 0 deletions
diff --git a/sci-libs/proj/proj-6.2.0.ebuild b/sci-libs/proj/proj-6.2.0.ebuild
new file mode 100644
index 000000000000..ec883d6bb8cf
--- /dev/null
+++ b/sci-libs/proj/proj-6.2.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="PROJ coordinate transformation software"
+HOMEPAGE="https://proj4.org/"
+DATUMGRID="${PN}-datumgrid-1.8.tar.gz"
+EUROPE_DATUMGRID="${PN}-datumgrid-europe-1.4.tar.gz"
+SRC_URI="
+	https://download.osgeo.org/proj/${P}.tar.gz
+	https://download.osgeo.org/proj/${DATUMGRID}
+	europe? ( https://download.osgeo.org/proj/${EUROPE_DATUMGRID} )
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="europe static-libs test"
+REQUIRED_USE="test? ( !europe )"
+
+RDEPEND="dev-db/sqlite:3"
+DEPEND="${RDEPEND}"
+
+src_unpack() {
+	unpack ${P}.tar.gz
+	cd "${S}"/data || die
+	mv README README.DATA || die
+	unpack ${DATUMGRID}
+	use europe && unpack ${EUROPE_DATUMGRID}
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		--without-jni
+}
+
+src_install() {
+	default
+	cd data || die
+	dodoc README.{DATA,DATUMGRID}
+	use europe && dodoc README.EUROPE
+	find "${D}" -name '*.la' -delete || die
+}