1 files changed, 50 insertions, 0 deletions
diff --git a/net-libs/libircclient/libircclient-1.6-r2.ebuild b/net-libs/libircclient/libircclient-1.6-r2.ebuild
new file mode 100644
index 000000000000..66d2da4a8b34
--- /dev/null
+++ b/net-libs/libircclient/libircclient-1.6-r2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools eutils
+
+DESCRIPTION="Small but powerful library implementing the client-server IRC protocol"
+HOMEPAGE="http://www.ulduzsoft.com/libircclient/"
+SRC_URI="mirror://sourceforge/libircclient/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="amd64 ppc x86"
+IUSE="doc ipv6 ssl static-libs threads"
+
+DEPEND="ssl? ( dev-libs/openssl )"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-build.patch \
+		"${FILESDIR}"/${P}-shared.patch \
+		"${FILESDIR}"/${P}-include.patch \
+		"${FILESDIR}"/${P}-static.patch
+	eautoconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable threads) \
+		$(use_enable ipv6) \
+		$(use_enable ssl openssl) \
+		$(use_enable ssl threads)
+}
+
+src_compile() {
+	emake -C src $(usex static-libs "shared static" "shared")
+}
+
+src_install() {
+	emake -C src DESTDIR="${D}" $(usex static-libs "install" "install-shared")
+	insinto /usr/include/libircclient
+	doins include/*.h
+
+	dodoc Changelog THANKS
+	if use doc ; then
+		doman doc/man/man3/*
+		dohtml doc/html/*
+	fi
+}