1 files changed, 45 insertions, 0 deletions
diff --git a/kde-apps/analitza/analitza-23.08.1.ebuild b/kde-apps/analitza/analitza-23.08.1.ebuild
new file mode 100644
index 000000000000..1537c0cd11e5
--- /dev/null
+++ b/kde-apps/analitza/analitza-23.08.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="KDE library for mathematical features"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="eigen"
+
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5[-gles2-only]
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	eigen? ( dev-cpp/eigen:3 )
+"
+RDEPEND="${DEPEND}"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+src_prepare() {
+	ecm_src_prepare
+
+	if ! use test; then
+		sed -i \
+			-e "/add_subdirectory(examples)/ s/^/#DONT/" \
+			analitzaplot/CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package eigen Eigen3)
+	)
+
+	ecm_src_configure
+}