1 files changed, 41 insertions, 0 deletions
diff --git a/dev-ruby/msgpack/msgpack-0.6.1.ebuild b/dev-ruby/msgpack/msgpack-0.6.1.ebuild
new file mode 100644
index 000000000000..2be64469ab79
--- /dev/null
+++ b/dev-ruby/msgpack/msgpack-0.6.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+USE_RUBY="ruby19 ruby20 ruby21 ruby22"
+
+RUBY_FAKEGEM_TASK_DOC="doc"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+RUBY_FAKEGEM_EXTRADOC="README.rdoc"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="Binary-based efficient data interchange format for ruby binding"
+HOMEPAGE="http://msgpack.org/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="doc"
+
+ruby_add_bdepend "doc? ( dev-ruby/yard )"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/I s:^:#:' Rakefile || die
+
+	# Remove jruby-specific specs that are run also for other rubies.
+	rm -rf spec/jruby
+
+	sed -i -e '/git ls-files/d' msgpack.gemspec || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/${PN} extconf.rb || die "Configuration of extension failed."
+}
+
+each_ruby_compile() {
+	emake V=1 -Cext/${PN}
+	cp ext/${PN}/msgpack$(get_modname) lib/${PN} || die "Unable to install msgpack library."
+}