1 files changed, 56 insertions, 0 deletions
diff --git a/dev-python/babel/babel-2.16.0.ebuild b/dev-python/babel/babel-2.16.0.ebuild
new file mode 100644
index 000000000000..6ff8408c4ce4
--- /dev/null
+++ b/dev-python/babel/babel-2.16.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=${PN,}
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+# see scripts/download_import_cldr.py
+CLDR_PV=45.0
+DESCRIPTION="Collection of tools for internationalizing Python applications"
+HOMEPAGE="
+	https://babel.pocoo.org/
+	https://pypi.org/project/babel/
+	https://github.com/python-babel/babel/
+"
+SRC_URI+="
+	https://unicode.org/Public/cldr/${CLDR_PV%.*}/cldr-common-${CLDR_PV}.zip
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
+
+# RDEPEND in BDEPEND for import_cldr.py usage, bug #852158
+BDEPEND="
+	app-arch/unzip
+	${RDEPEND}
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm babel/locale-data/*.dat || die
+	rm babel/global.dat || die
+	distutils-r1_src_prepare
+}
+
+python_configure() {
+	if [[ ! -f babel/global.dat ]]; then
+		"${EPYTHON}" scripts/import_cldr.py "${WORKDIR}"/common || die
+	fi
+}
+
+python_test() {
+	local -x TZ=UTC
+	epytest
+}