2 files changed, 0 insertions, 89 deletions
diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index de7953b79cd3..23ead4b17df6 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1,4 +1,3 @@
 DIST libinput-1.16.1.tar.xz 595548 BLAKE2B 497089248c2104ff7784b7d46d8e846047e054f01c6ea192f1c41171b39213fa1f19be8c8253c32f988bfc6f025d2519697256ffaf62884182c511bcd5c5d335 SHA512 86b2d563c2cff2b3d3cae3acdd399030cc785cc9859a06357a99565ef51f95122a8427c8c0883121fb0760613460a29c8cd8c7a7e3ac68115c10330b3b75cbe0
-DIST libinput-1.16.2.tar.xz 595632 BLAKE2B 0010ee7495e35d093d9cff72195433cfd571fb0b6d2bfbfa61b19eb6baa6cf6d00728673408d9d2427c3cb948e146ffd5a0184fe9a7ca3cc9bf8889b64a55115 SHA512 3394faeb0cdb0a543624e150f04a98f3bce8d67438e47455808bde8eec8ea9cdafb86056e5f8d3431352ae33714e490c55edeb51e0af1972c68fca07c1ef1daa
 DIST libinput-1.16.3.tar.xz 594948 BLAKE2B 6fad03dc8ab0280435b89a1049ed019d29e795279273277c9cad4676f484856d2677845ddc1c5102f2430645053a77c1cde48bb32530d4290ade576843a51ded SHA512 cdf87988b24dc0a44b7b6ed3e15e70c7702bf65f1cfe257924967677c7a1f1485011a9e30254ba8962c83885de78f824e7955cedb07322676332d42532ec4a39
 DIST libinput-1.16.4.tar.xz 596028 BLAKE2B ad2160d83bcbdd65383272e0c4b35e35c7b46a6d0c771d7c0188c92b204d57dae73d0820bb93f662f155c1eab19c0195110f5a18a68de890c808925d5c056814 SHA512 a95a3bcf58a9298946d15f4f2fd93dc5807d3042f8797950a1ffd96d3c979b55a764f035a9f7680d0ea400b033698c322eb61a4387dbc280db6110ffd3e137ee
diff --git a/dev-libs/libinput/libinput-1.16.2.ebuild b/dev-libs/libinput/libinput-1.16.2.ebuild
deleted file mode 100644
index e2ae19212794..000000000000
--- a/dev-libs/libinput/libinput-1.16.2.ebuild
+++ /dev/null
@@ -1,88 +0,0 @@
-# Copyright 2014-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-PYTHON_COMPAT=( python3_{6,7,8} )
-
-inherit meson python-any-r1 udev
-
-DESCRIPTION="Library to handle input devices in Wayland"
-HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
-SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
-
-LICENSE="MIT"
-SLOT="0/10"
-[[ "$(ver_cut 3)" -gt 900 ]] || \
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
-IUSE="doc input_devices_wacom test"
-RESTRICT="!test? ( test )"
-
-BDEPEND="
-	virtual/pkgconfig
-	doc? (
-		$(python_gen_any_dep '
-			dev-python/commonmark[${PYTHON_USEDEP}]
-			dev-python/recommonmark[${PYTHON_USEDEP}]
-			dev-python/sphinx[${PYTHON_USEDEP}]
-			>=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
-		')
-		>=app-doc/doxygen-1.8.3
-		>=media-gfx/graphviz-2.38.0
-	)
-"
-#	test? ( dev-util/valgrind )
-RDEPEND="
-	input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
-	>=dev-libs/libevdev-1.3
-	>=sys-libs/mtdev-1.1
-	virtual/libudev:=
-	virtual/udev
-"
-DEPEND="${RDEPEND}
-	test? ( >=dev-libs/check-0.9.10 )"
-
-python_check_deps() {
-	has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
-	has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
-	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
-	has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	use doc && python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-	sed "s@, '-Werror'@@" -i meson.build || die #744250
-}
-
-src_configure() {
-	# gui can be built but will not be installed
-	local emesonargs=(
-		-Ddebug-gui=false
-		$(meson_use doc documentation)
-		$(meson_use input_devices_wacom libwacom)
-		$(meson_use test tests)
-		-Dudev-dir="${EPREFIX}$(get_udevdir)"
-	)
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-	if use doc ; then
-		docinto html
-		dodoc -r "${BUILD_DIR}"/Documentation/.
-	fi
-}
-
-pkg_postinst() {
-	pkgname="dev-python/python-libevdev"
-	if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version "${pkgname}" ; then
-		einfo "${pkgname} must be installed to use the"
-		einfo "libinput measure and libinput replay tools."
-	fi
-
-	udevadm hwdb --update --root="${ROOT}"
-}