xfce-base/xfce4-settings: Bump to 4.18.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/xfce-base/xfce4-settings/Manifest b/xfce-base/xfce4-settings/Manifest
index 7759476bc225..30f537ed619c 100644
--- a/xfce-base/xfce4-settings/Manifest
+++ b/xfce-base/xfce4-settings/Manifest
@@ -1,2 +1,3 @@
 DIST xfce4-settings-4.18.4.tar.bz2 1557097 BLAKE2B 0269ed1778becc547ba187c096d7c9938cc00f56fb1c9312c9d0eb9b5344d4785f88abadecf391724699de2cb28b35ffed057f06e85f3e098a902a4047969a9c SHA512 2f9e2de4a3a0cc59b4701b44899464532fbae8805270485d2821b65b9d78be54bb636c4cd4205de97e18c13b20912fcd1f4ca0b3baa561bf1a783829f53a06a0
+DIST xfce4-settings-4.18.5.tar.bz2 1559812 BLAKE2B 3639cb17dbe9311556de03f5ae497ab7b18fa170e64cfab2c414194bb544b370a2d82df0344a859b4b0b7438dc1e0046b5e8519206553decbf8bf3def5534503 SHA512 706407131bf4c78d5b5a7604444c76b4c8e84444d48ca145d9934b3e2facc9117762ac3f05ef54ea0275b80d96ab54a0a174f1799f949710c436744fe42dcabd
 DIST xfce4-settings-4.19.2.tar.bz2 2433368 BLAKE2B 00175d94837c0abec841feed5d1ea834160afccae8718f4af11323d65d5d751d288dd2651b06ceee6ec02fa2ec222e5b94322a38fa59fd29a18e64a1eb84c88c SHA512 dc225dc3d4296db1dbfdd93685a29b453faab2c3259e2dd1f162d631b3853c4f2b582facab60814d1babe934c2eac752ef954dff2b285e9340dd5247f131555a
diff --git a/xfce-base/xfce4-settings/xfce4-settings-4.18.5.ebuild b/xfce-base/xfce4-settings/xfce4-settings-4.18.5.ebuild
new file mode 100644
index 000000000000..bca7a8b05d91
--- /dev/null
+++ b/xfce-base/xfce4-settings/xfce4-settings-4.18.5.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit python-single-r1 xdg-utils
+
+DESCRIPTION="Configuration system for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-settings/start
+	https://gitlab.xfce.org/xfce/xfce4-settings/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="colord input_devices_libinput libcanberra libnotify upower +xklavier"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.66.0
+	media-libs/fontconfig
+	>=x11-libs/gtk+-3.24.0:3
+	x11-libs/libX11
+	>=x11-libs/libXcursor-1.1
+	>=x11-libs/libXi-1.3
+	>=x11-libs/libXrandr-1.2
+	>=xfce-base/garcon-0.2:=
+	>=xfce-base/exo-4.15.1:=
+	>=xfce-base/libxfce4ui-4.17.0:=
+	>=xfce-base/libxfce4util-4.17.2:=
+	>=xfce-base/xfconf-4.13:=
+	colord? ( x11-misc/colord:= )
+	libcanberra? ( >=media-libs/libcanberra-0.25[sound] )
+	input_devices_libinput? ( x11-drivers/xf86-input-libinput )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	upower? ( >=sys-power/upower-0.9.23 )
+	xklavier? ( >=x11-libs/libxklavier-5 )
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext
+"
+
+src_prepare() {
+	default
+	python_fix_shebang dialogs/mime-settings/helpers/xfce4-compose-mail
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable upower upower-glib)
+		$(use_enable input_devices_libinput xorg-libinput)
+		$(use_enable libnotify)
+		$(use_enable colord)
+		$(use_enable xklavier libxklavier)
+		$(use_enable libcanberra sound-settings)
+	)
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}