x11-wm/xpra: Version bump.

Package-Manager: Portage-2.3.5, Repoman-2.3.2

2 files changed, 145 insertions, 0 deletions

diff --git a/x11-wm/xpra/Manifest b/x11-wm/xpra/Manifest
index 36ca3a59cc35..a8d0d9eee506 100644
--- a/x11-wm/xpra/Manifest
+++ b/x11-wm/xpra/Manifest
@@ -1,3 +1,4 @@
 DIST xpra-1.0.3.tar.xz 1888908 SHA256 f83c5946f67fe26eee8b44fba0fa30bca9fbc7aa58ee66b903b7385c2d332166 SHA512 3b6371d478147a5d932df1c8428e9132831fcbf17e51f48fb384c30548efee9758c94a6781c255b5fe211c5040993f30b054aa33f3fced85484fcc9d2ca009a1 WHIRLPOOL 989db8ac2caa3a5a0e1294754cabe6bc8cadb087a6ffa24de3039c674126886a41ecab930c46700dccdf3adc738572e04652123c9523512c050ffdff3d295b02
 DIST xpra-1.0.4.tar.xz 1890404 SHA256 c841940957761e60454eac44c955d174b3d864c853f28b387e784a6d85fc9924 SHA512 85dad598a167a7c9cbf2d0e7d4cde0b7c0fd75b5e1cc515ea78261f4a33d6d864863f98746f7537b202a08c7f225f002d9abbbb5c2773acd63e3a1b37c4d68d9 WHIRLPOOL e426a258b70dcb1dff9f39980fd74221ab5793ea4f8cea2b838dfcd40b152785ef7028219f0024ef4650bb9e6fae10e9d26c1b1e58f0b4efb481a7562f6ee4eb
+DIST xpra-2.0.1.tar.xz 1926292 SHA256 685553c0f7cdeadde3d5a7ba48f3cd9d0feaa755e0debbdf198355223c8bc287 SHA512 2f9a8f5f3c1980c822233c3b010511d7ac63983eff330222e7375257834dfd6c840fe4b4aba61b966fb3b14debfed05eb1cd724f502a7c7b7ee9fbc86becbac3 WHIRLPOOL e5ef03c29988fa5cf10bb83eb010ac0464a95c4511d7e7ec08349ee5a53f2391f69c95fd3b5d8bb19fe29dec29ec40a273dc35d992912722594972864bd983e4
 DIST xpra-2.0.tar.xz 1925080 SHA256 ca9e9622a9d435f9591bf60baec50ea02ebad4e0c0017e1df43dfddd6616e807 SHA512 1f95ecf27c1ef37989c2152a1b2b838f5246a6e3711feaa2150d55b040a41ee0de1d475eb68900b974ee9f7b3f3cf143d53802420f31de60980658cd6da132c6 WHIRLPOOL 3f72416011e35513a0acd62980f49af286d2411446452a4a336746a94c813f7f0b316061fcb854efe377d7bc77152e5eb7930d7b3afb863ea30f9e01186e4efe
diff --git a/x11-wm/xpra/xpra-2.0.1.ebuild b/x11-wm/xpra/xpra-2.0.1.ebuild
new file mode 100644
index 000000000000..44f38c25618d
--- /dev/null
+++ b/x11-wm/xpra/xpra-2.0.1.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# PyCObject_Check and PyCObject_AsVoidPtr vanished with python 3.3
+PYTHON_COMPAT=( python2_7 )
+inherit distutils-r1 eutils flag-o-matic user tmpfiles
+
+DESCRIPTION="X Persistent Remote Apps (xpra) and Partitioning WM (parti) based on wimpiggy"
+HOMEPAGE="http://xpra.org/ http://xpra.org/src/"
+SRC_URI="http://xpra.org/src/${P}.tar.xz"
+
+LICENSE="GPL-2 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+client +clipboard csc cups dbus dec_avcodec2 enc_ffmpeg enc_x264 enc_x265 jpeg libav +lz4 lzo opengl pillow pulseaudio server sound test vpx webcam"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	clipboard? ( || ( server client ) )
+	cups? ( dbus )
+	opengl? ( client )
+	|| ( client server )
+	client? ( enc_x264? ( dec_avcodec2 ) enc_x265? ( dec_avcodec2 ) )"
+
+COMMON_DEPEND=""${PYTHON_DEPS}"
+	dev-python/pygobject:2[${PYTHON_USEDEP}]
+	dev-python/pygtk:2[${PYTHON_USEDEP}]
+	x11-libs/gtk+:2
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libXtst
+	csc? (
+		!libav? ( >=media-video/ffmpeg-1.2.2:0= )
+		libav? ( media-video/libav:0= )
+	)
+	dec_avcodec2? (
+		!libav? ( >=media-video/ffmpeg-2:0= )
+		libav? ( media-video/libav:0= )
+	)
+	enc_ffmpeg? (
+		!libav? ( >=media-video/ffmpeg-3.2.2:0= )
+		libav? ( media-video/libav:0= )
+	)
+	enc_x264? ( media-libs/x264
+		!libav? ( >=media-video/ffmpeg-1.0.4:0= )
+		libav? ( media-video/libav:0= )
+	)
+	enc_x265? ( media-libs/x265
+		!libav? ( >=media-video/ffmpeg-2:0= )
+		libav? ( media-video/libav:0= )
+	jpeg? ( media-libs/libjpeg-turbo )
+	opengl? ( dev-python/pygtkglext )
+	pulseaudio? ( media-sound/pulseaudio )
+	sound? ( media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		dev-python/gst-python:1.0 )
+	vpx? ( media-libs/libvpx virtual/ffmpeg )
+	)"
+
+RDEPEND="${COMMON_DEPEND}
+	dev-python/ipython[${PYTHON_USEDEP}]
+	dev-python/netifaces[${PYTHON_USEDEP}]
+	dev-python/rencode[${PYTHON_USEDEP}]
+	virtual/ssh
+	x11-apps/xmodmap
+	cups? ( dev-python/pycups[${PYTHON_USEDEP}] )
+	dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+	lz4? ( dev-python/lz4[${PYTHON_USEDEP}] )
+	lzo? ( >=dev-python/python-lzo-0.7.0[${PYTHON_USEDEP}] )
+	opengl? (
+		client? ( dev-python/pyopengl_accelerate[${PYTHON_USEDEP}] )
+	)
+	pillow? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	server? ( x11-base/xorg-server[-minimal,xvfb]
+		x11-drivers/xf86-input-void
+	)
+	webcam? ( dev-python/numpy[${PYTHON_USEDEP}]
+		media-libs/opencv[python]
+		dev-python/pyinotify[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+	>=dev-python/cython-0.16[${PYTHON_USEDEP}]"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.13.1-ignore-gentoo-no-compile.patch
+	"${FILESDIR}"/${PN}-0.17.4-deprecated-avcodec.patch
+	"${FILESDIR}"/${PN}-2.0-suid-warning.patch )
+
+pkg_postinst() {
+	enewgroup ${PN}
+	tmpfiles_process /usr/lib/tmpfiles.d/xpra.conf
+}
+
+python_prepare_all() {
+	sed -e "s:/var/run/xpra:${EROOT}run/xpra:" \
+		-i tmpfiles.d/xpra.conf
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	sed -e "/'pulseaudio'/s:DEFAULT_PULSEAUDIO:$(usex pulseaudio True False):" \
+		-i setup.py || die
+
+	mydistutilsargs=(
+		--without-PIC
+		--without-Xdummy
+		$(use_with client)
+		$(use_with clipboard)
+		$(use_with csc csc_swscale)
+		--without-csc_libyuv
+		$(use_with cups printing)
+		--without-debug
+		$(use_with dbus)
+		$(use_with dec_avcodec2)
+		$(use_with enc_ffmpeg)
+		$(use_with enc_x264)
+		$(use_with enc_x265)
+		--with-gtk2
+		--without-gtk3
+		--without-html5
+		$(use_with jpeg)
+		--without-mdns
+		--without-minify
+		$(use_with opengl)
+		$(use_with server shadow)
+		$(use_with server)
+		$(use_with sound)
+		--with-strict
+		$(use_with vpx)
+		--with-warn
+		$(use_with webcam)
+		--with-x11
+	)
+
+	# see https://www.xpra.org/trac/ticket/1080
+	# and http://trac.cython.org/ticket/395
+	append-cflags -fno-strict-aliasing
+
+	export XPRA_SOCKET_DIRS="${EROOT}run/xpra"
+}