x11-misc/lightdm-gtk-greeter: Bump to version 2.0.8

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 84 insertions, 0 deletions

diff --git a/x11-misc/lightdm-gtk-greeter/Manifest b/x11-misc/lightdm-gtk-greeter/Manifest
index 4e2dd430a776..84118abf4b67 100644
--- a/x11-misc/lightdm-gtk-greeter/Manifest
+++ b/x11-misc/lightdm-gtk-greeter/Manifest
@@ -1,3 +1,4 @@
 DIST lightdm-gentoo-patch-2.tar.gz 695543 BLAKE2B 62e21dd413b90053160f774663d89c81b3c9d8c4a040023f4ce50bf775a2f036e0be6ed16ae767eb5b04586a27fdbf41eb56f777340b2d56633738a126c3d575 SHA512 8d9bfdee71ab1871de33e134b11bba409cc493876e5ae9534956100ff6af6c8748b29de9082ecf8b771ccac4c8c2024e15e93332165171dfe93eb99c9a834274
 DIST lightdm-gtk-greeter-2.0.6.tar.gz 575668 BLAKE2B 6aa5e4db80f411b5a5e34c5ce332906a11d7755af71f617dfedf1658c60777ba732e0ed81a9d5e01c93e2a7fd74364dffc8043d640cd6ab91f3e604769863c01 SHA512 778215351a9140f164c67c75d69efc55b1edf97a493f42a14e2a40e322f738cba99534274d00198291454466fbf407efdc927479c4821d04e12d742feb31cc3a
 DIST lightdm-gtk-greeter-2.0.7.tar.gz 580726 BLAKE2B 1cb2a92a9bda0e28b718cf033ad01e8a8a955600715c61bc5f27723a1b5f4a4624caa61bbe9bdca13064919116f5f08959db2622a5d6b097998d762ffd9cfc28 SHA512 62ad8d522db9aeea7bd0acc76c989a1d39e8be619847b294048530b2dfbebf5a5982f84daf1a5f49b0a8a7abe3234e1571fb5d4f5429b02867801015f30e4944
+DIST lightdm-gtk-greeter-2.0.8.tar.gz 583426 BLAKE2B ae06ebbc07efe5c0131c07b293671f24683699eb84f12222de8165428e935b98bbf9d1e107eaeca8f10e725a6a11c97d4f4c3d415ada0b0876b0b0a99f21d1ee SHA512 59cad69fd7f17b6a416944804be80f306ed51ee0c55826975c8564f432e8098043b677f6452e9afa290c6ef37ebdc632cd8b79e7a0a712a3407ddbf9f200b0db
diff --git a/x11-misc/lightdm-gtk-greeter/lightdm-gtk-greeter-2.0.8.ebuild b/x11-misc/lightdm-gtk-greeter/lightdm-gtk-greeter-2.0.8.ebuild
new file mode 100644
index 000000000000..8824bc8e07e2
--- /dev/null
+++ b/x11-misc/lightdm-gtk-greeter/lightdm-gtk-greeter-2.0.8.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools xdg-utils
+
+DESCRIPTION="LightDM GTK+ Greeter"
+HOMEPAGE="https://github.com/Xubuntu/lightdm-gtk-greeter"
+SRC_URI="https://github.com/Xubuntu/${PN}/releases/download/${P}/${P}.tar.gz
+	branding? ( https://dev.gentoo.org/~polynomial-c/dist/lightdm-gentoo-patch-2.tar.gz )"
+
+LICENSE="GPL-3 LGPL-3
+	branding? ( CC-BY-3.0 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="appindicator branding"
+
+DEPEND="appindicator? ( dev-libs/libindicator:3 )
+	x11-libs/gtk+:3
+	>=x11-misc/lightdm-1.2.2"
+
+BDEPEND="
+	dev-util/intltool
+	dev-util/xfce4-dev-tools
+	sys-devel/gettext
+"
+
+RDEPEND="${DEPEND}
+	x11-themes/gnome-themes-standard
+	>=x11-themes/adwaita-icon-theme-3.14.1"
+
+GENTOO_BG="gentoo-bg_65.jpg"
+
+src_prepare() {
+	# Ok, this has to be fixed in the tarball but I am too lazy to do it.
+	# I will fix this once I decide to update the tarball with a new gentoo
+	# background
+	# Bug #404467
+	if use branding; then
+		sed \
+			-e "/xft-hintstyle/s:slight:hintslight:" \
+			-e "/background/s:=.*:=/usr/share/lightdm/backgrounds/${GENTOO_BG}:" \
+			-i "${WORKDIR}"/${PN}.conf || die
+		# Add back the reboot/shutdown buttons
+		echo 'indicators=~host;~spacer;~clock;~spacer;~session;~language;~a11y;~power;~' \
+			>> "${WORKDIR}"/${PN}.conf || die
+	fi
+	default
+
+	# Fix docdir
+	sed "/^docdir/s@${PN}@${PF}@" -i data/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-kill-on-sigterm
+		--enable-at-spi-command="${EPREFIX}/usr/libexec/at-spi-bus-launcher --launch-immediately"
+		$(use_enable appindicator libindicator)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if use branding; then
+		insinto /etc/lightdm/
+		doins "${WORKDIR}"/${PN}.conf
+		insinto /usr/share/lightdm/backgrounds/
+		doins "${WORKDIR}"/${GENTOO_BG}
+		newdoc "${WORKDIR}"/README.txt README-background.txt
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}