x11-libs/xapps: 1.8.9 version bump

Fix python_optimize handling. Upstream renamed to xapp.

Bug: https://bugs.gentoo.org/733544
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 89 insertions, 0 deletions

diff --git a/x11-libs/xapps/Manifest b/x11-libs/xapps/Manifest
index aaa8dbcf4ab2..434748fee239 100644
--- a/x11-libs/xapps/Manifest
+++ b/x11-libs/xapps/Manifest
@@ -1,2 +1,3 @@
 DIST xapps-1.4.2.tar.gz 69709 BLAKE2B 514e4cb2e614ccd9fa303625eb5ffb818847447b29d6d989c2abdc90b6b9840dac6124d8484b71ffc2e489a925f83dae597c0904aa79cd5d5a0c27d44420da96 SHA512 2d16bd893a16876270c41d755c62ca454f561931750acc719c480e63036b70dca8dae25e6a313f13ed0daae09fd650e0efcef9d272c405ccd9c04147aaf59fe2
 DIST xapps-1.8.4.tar.gz 179340 BLAKE2B f6558b87320cbd73e73c5294f48a3c0c94c7239abc9ede9cd88e66ccd53fd0c9cba9c638837efbd5eecd8a4f372262fde759e05ba9e97ad9955ab74464c34c21 SHA512 483e8e334d4883e2172e06835d690d20af2752fcc195f63776053b83abc0ffcb25c757633450a02b153e70e67e98c477754de12169c167a2f9f3fea103e12bad
+DIST xapps-1.8.9.tar.gz 187789 BLAKE2B 37b2d2677cb6483533d79853a83d77b30033313c06db89e93491076bb017122f77cd97b30d5ba64ce53fb41a37736791e97da785f516953b76b1d979d341e2fc SHA512 95dd1cbf84b59adf6682d9025e0cfa7a414c24d4f584cde87d0cc6ea82c06338de2c320dad8d997e105980782ec5cb23f0def6f6d60ea84be7d74c90d7cd692c
diff --git a/x11-libs/xapps/xapps-1.8.9.ebuild b/x11-libs/xapps/xapps-1.8.9.ebuild
new file mode 100644
index 000000000000..978f4e8c17e8
--- /dev/null
+++ b/x11-libs/xapps/xapps-1.8.9.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+VALA_USE_DEPEND="vapigen"
+inherit gnome2-utils vala meson python-r1 xdg-utils
+
+DESCRIPTION="Cross-desktop libraries and common resources"
+HOMEPAGE="https://github.com/linuxmint/xapp/"
+LICENSE="GPL-3"
+
+SRC_URI="https://github.com/linuxmint/xapp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/xapp-${PV}"
+KEYWORDS="~amd64 ~x86"
+
+SLOT="0"
+IUSE="gtk-doc introspection static-libs"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.37.3:2
+	dev-libs/gobject-introspection:0=
+	gnome-base/libgnomekbd
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.22.0:2[introspection?]
+	>=x11-libs/gtk+-3.3.16:3[introspection?]
+	x11-libs/libxkbfile
+	dev-libs/libdbusmenu[gtk3]
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	gtk-doc? ( dev-util/gtk-doc )
+	$(vala_depend)
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-util/gdbus-codegen
+	>=dev-util/intltool-0.40.6
+	sys-devel/gettext
+"
+
+src_prepare() {
+	xdg_environment_reset
+	vala_src_prepare
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dpy-overrides-dir="/pygobject"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	rm -rf "${ED}/usr/bin" || die
+
+	# package provides .pc files
+	find "${D}" -name '*.la' -delete || die
+
+	# copy pygobject files to each active python target
+	# work-around for "py-overrides-dir" only supporting a single target
+	install_pygobject_override() {
+		PYTHON_GI_OVERRIDESDIR=$("${PYTHON}" -c 'import gi;print(gi._overridesdir)') || die
+		einfo "gobject overrides directory: $PYTHON_GI_OVERRIDESDIR"
+		mkdir -p "${ED}/$PYTHON_GI_OVERRIDESDIR/"
+		cp -r "${D}"/pygobject/* "${ED}/$PYTHON_GI_OVERRIDESDIR/" || die
+		python_optimize "${ED}/$PYTHON_GI_OVERRIDESDIR/"
+	}
+	python_foreach_impl install_pygobject_override
+	rm -rf "${D}/pygobject" || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}