x11-apps/python-whiteboard: Port to python-single-r1

Package-Manager: Portage-2.3.3, Repoman-2.3.1

2 files changed, 51 insertions, 0 deletions

diff --git a/x11-apps/python-whiteboard/files/python-whiteboard-20101012-fix-desktop-qa.patch b/x11-apps/python-whiteboard/files/python-whiteboard-20101012-fix-desktop-qa.patch
new file mode 100644
index 000000000000..c27b88b767ec
--- /dev/null
+++ b/x11-apps/python-whiteboard/files/python-whiteboard-20101012-fix-desktop-qa.patch
@@ -0,0 +1,14 @@
+Fix .desktop file to adhere to modern FDO standards.
+
+--- a/dist/python-whiteboard.desktop
++++ b/dist/python-whiteboard.desktop
+@@ -3,7 +3,7 @@
+ Type=Application
+ Encoding=UTF-8
+ Name=python-whiteboard
+-Icon=pywb_pixmap.xpm
++Icon=pywb_pixmap
+ Exec=/usr/bin/python-whiteboard
+-Categories=Application;Education
++Categories=Education
+ 
diff --git a/x11-apps/python-whiteboard/python-whiteboard-20101012-r1.ebuild b/x11-apps/python-whiteboard/python-whiteboard-20101012-r1.ebuild
new file mode 100644
index 000000000000..9b20439854ff
--- /dev/null
+++ b/x11-apps/python-whiteboard/python-whiteboard-20101012-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-single-r1
+
+DESCRIPTION="Build and operate a electronic whiteboard Wiimote and IR Pen"
+HOMEPAGE="https://github.com/pnegre/python-whiteboard"
+SRC_URI="https://dev.gentoo.org/~lxnay/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	app-misc/cwiid[python,${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pybluez[${PYTHON_USEDEP}]
+	dev-python/PyQt4[${PYTHON_USEDEP}]
+	dev-python/python-xlib[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}"/${PN}-20101012-fix-desktop-qa.patch )
+
+src_install() {
+	default
+
+	# install correctly in python sitedir
+	python_domodule "${ED%/}"/usr/lib/python-whiteboard
+	rm -r "${ED%/}"/usr/lib || die
+}