www-apache/mod_auth_openidc: new package, move from infra overlay

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>

4 files changed, 90 insertions, 0 deletions

diff --git a/www-apache/mod_auth_openidc/Manifest b/www-apache/mod_auth_openidc/Manifest
new file mode 100644
index 000000000000..996d5dfef207
--- /dev/null
+++ b/www-apache/mod_auth_openidc/Manifest
@@ -0,0 +1 @@
+DIST mod_auth_openidc-2.4.14.4.tar.gz 632757 BLAKE2B e01df9c431df848c1773f8152d87b5efc183b016516718bbf5eff3de66d12c87396b649a06548b5f0e42a52d08baef9ced8cd4b79acfc1657b7427dab0c9c14d SHA512 b7d61f15d48292f2a567653632f7d9df8b6cb54303d4de0c333c8122a32df8749e508a0abd5259ac7ca15da5b244eec1e1d21f62140720ddb1705ec289551984
diff --git a/www-apache/mod_auth_openidc/files/10_mod_auth_openidc.conf b/www-apache/mod_auth_openidc/files/10_mod_auth_openidc.conf
new file mode 100644
index 000000000000..0290c4cfc162
--- /dev/null
+++ b/www-apache/mod_auth_openidc/files/10_mod_auth_openidc.conf
@@ -0,0 +1,4 @@
+<IfDefine AUTH_OPENIDC>
+LoadModule auth_openidc_module modules/mod_auth_openidc.so
+# See /usr/share/doc/mod_auth_openidc-*/auth_openidc.conf for configuration options.
+</IfDefine>
diff --git a/www-apache/mod_auth_openidc/metadata.xml b/www-apache/mod_auth_openidc/metadata.xml
new file mode 100644
index 000000000000..13dbd324eab0
--- /dev/null
+++ b/www-apache/mod_auth_openidc/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>robbat2@gentoo.org</email>
+	</maintainer>
+	<maintainer type="project">
+		<email>infra@gentoo.org</email>
+		<name>Gentoo Infrastructure Team</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">OpenIDC/mod_auth_openidc</remote-id>
+	</upstream>
+	<use>
+		<flag name="redis">Add support for the Redis caching via <pkg>dev-libs/hiredis</pkg></flag>
+		<flag name="brotli">Add support for brotli compressed data using <pkg>app-arch/brotli</pkg></flag>
+	</use>
+</pkgmetadata>
diff --git a/www-apache/mod_auth_openidc/mod_auth_openidc-2.4.14.4-r1.ebuild b/www-apache/mod_auth_openidc/mod_auth_openidc-2.4.14.4-r1.ebuild
new file mode 100644
index 000000000000..4ab411903ee7
--- /dev/null
+++ b/www-apache/mod_auth_openidc/mod_auth_openidc-2.4.14.4-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+#
+
+EAPI=8
+
+inherit depend.apache apache-module autotools
+
+DESCRIPTION="OpenID Connect Relying Party implementation for Apache HTTP Server 2.x"
+HOMEPAGE="https://github.com/OpenIDC/mod_auth_openidc"
+SRC_URI="https://github.com/OpenIDC/mod_auth_openidc/releases/download/v${PV}/${P}.tar.gz"
+KEYWORDS="~amd64"
+IUSE="redis brotli"
+
+SLOT="0"
+LICENSE="Apache-2.0"
+
+RDEPEND="net-misc/curl
+	brotli? ( app-arch/brotli:= )
+	sys-libs/zlib:=
+	dev-libs/openssl:=
+	dev-libs/apr
+	dev-libs/jansson:=
+	dev-libs/cjose
+	dev-libs/libpcre
+	redis? ( dev-libs/hiredis:= )
+	app-misc/jq"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig"
+
+APACHE2_MOD_CONF="10_mod_auth_openidc"
+APACHE2_MOD_DEFINE="AUTH_OPENIDC"
+DOCFILES="README.md ChangeLog AUTHORS INSTALL auth_openidc.conf"
+
+need_apache2_4
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	ECONF_ARGS=(
+		$(use_with brotli)
+		$(use_with redis hiredis)
+	)
+	econf "${ECONF_ARGS[@]}"
+}
+
+src_compile() {
+	# Do not use apache-module_src_compile ; it does not compile properly
+	default
+}
+
+src_install() {
+	# Do not use apache-module_src_install ; it does not link properly
+	default
+
+	insinto "${APACHE_MODULES_CONFDIR}"
+	doins "${FILESDIR}/${APACHE2_MOD_CONF}.conf"
+	dodoc ${DOCFILES}
+}
+
+pkg_postinst() {
+	apache-module_pkg_postinst
+}