sys-kernel/gentoo-kernel-bin: add 5.14.21-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 9bacf2bc1bca..41694cc05daf 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -36,6 +36,7 @@ DIST gentoo-kernel-5.14.20-1.amd64.xpak 68144100 BLAKE2B fef36b61841ab6f5bea3f30
 DIST gentoo-kernel-5.14.20-1.arm64.xpak 63105775 BLAKE2B 6a5eabe8c298a767f8058887fcc610cd3c59d70a14eea5a6ec9af5192a16136d0fac7103c1db6563ee922a6229b8a9be7762e9f47a57a9a4dcce41d45615197a SHA512 d155f1ec48deb43edf569c6be6c44b411dc41148bb393047df726a23ae128093b3f4337e35e9641e48849507b59e8f90ec974508fd5ca80b27ea0eb5df7e2600
 DIST gentoo-kernel-5.14.20-1.x86.xpak 59196770 BLAKE2B 53d9544223b5a2dff33e46d63c3b02f3f05ab4b1702780d3648d6d6c770069750ab4fc96f07b55cda993bd332a977db562456f591ba2890aea786585d6793c92 SHA512 6d7cf027e366c45cacd014252f9b79ac78cdc18b450746546ebbf8506da5361262795f2921b00485a1659a5ec7bf6498e0b6d4c9c19649cb9a17498687fc73f2
 DIST gentoo-kernel-5.14.21-1.amd64.xpak 68158912 BLAKE2B b9279d59dfd6efd34660ac67045510048dd308cdd44b4626d3f5d24076caf2a2cae772cfa16e8d0bb8cb0ef2ad77309bba0e54d13a1239da8fe89be5ca3166c0 SHA512 04d399c11ece91e39b6034748fb0fda0ce13b3edc277eabdee2107f5f1264fe183c446b5b47db8175c8eeff124f8b5cdb506c436476ded3b016621abfaeac30c
+DIST gentoo-kernel-5.14.21-1.arm64.xpak 63079807 BLAKE2B e9bff436f4183e55f17b923386d10afaeecedfdead7b386ace028dae0364082f76c63688d4f91fb259999e1e635dc98cfefe220d5b117a4d34b1648c90b3f93e SHA512 87f9ff1f35ef16dc842dcb9dd8ed68e6c39a45f1f0887498aa61dbab1f30e551f525ebfea6c710ed2a907a54b9a92cb99e4f5f3a719d0fdc0314a37e981fcf41
 DIST gentoo-kernel-5.14.21-1.x86.xpak 59244096 BLAKE2B c16154db406ac9c6626e5c37a33dfaf53c4051b37dd9719a6cf164d378b8bb4f419018ce2d944e8c4b63706e53061c7f9f80dd43bb8c9fbe7ccfdb18ccf830c3 SHA512 5df36eca258f0258b4c66b60511c7e92c5127b448eba6930d94bec83543053169a91ad349c65616dcfd21141bae984f85b4118eb47472b8a2319a5f1a80aca78
 DIST gentoo-kernel-5.15.3-1.amd64.xpak 68950522 BLAKE2B 513ed80336aa6d16af4a1341a715f43383d5e0926337eded78a35f749a028b78be98905a3af119fa7560347d559a225852ab34ca541092ee703a617c1ca1deb9 SHA512 9db9590dd30ca82a0cd914c869c46e041a5f3187ab9e318a836e40cecd6baa0dce541e6a2c428c90ebfbb8ca66243aa7a84af849bc0780e5dcc19937dd4e93ff
 DIST gentoo-kernel-5.15.3-1.x86.xpak 59771064 BLAKE2B 2ab6d9f879543e4c68dd528e5e11513512acae13d39856a8ea88c9e3bb114749d872ad22f485229cbd88b542a3e8c1789b71fe317a4547c7dbd545ada28e5d53 SHA512 17a5b0647cf1cca9c6337f48c9ffb280f339201648aa97581a562fb538f918f4b5bc26553f41cd9e566b3f2534d6533a8c101e4823f531d891c5f05f6b1cd03e
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.21-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.21-r1.ebuild
new file mode 100644
index 000000000000..b392a3e75a53
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.21-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}