sys-cluster/cinder: 11.0.2 bup

Package-Manager: Portage-2.3.14, Repoman-2.3.6

2 files changed, 210 insertions, 0 deletions

diff --git a/sys-cluster/cinder/Manifest b/sys-cluster/cinder/Manifest
index cc891e44da41..799f0e702ca3 100644
--- a/sys-cluster/cinder/Manifest
+++ b/sys-cluster/cinder/Manifest
@@ -1,5 +1,6 @@
 DIST cinder-10.0.6.tar.gz 4624145 BLAKE2B c3e12c4f49b9b06b674d12354e867328eaaef565930ac1d3078c4611f14f61463d458a2bfd679a0a6cb8ce5b677b037618a800d229bf352797b20b57c8383e6b SHA512 28c84260909d0c1a9b0cd6a7409dad3e09d0d7bd662b8ca61c6c3ca04fb797723bc0f4df7db3a6951d1ce354a84b907bf1832190c02a5992c8ac70cf95fb00b9
 DIST cinder-11.0.1.tar.gz 5805313 BLAKE2B 00ce0b1992d561c25052c4b810b1e1c8a2f5610d7f3d20c25007a9f59e639e9a5b549f13d454632a432cb81d1d9c75cfb5f6683c688185645bfc0e4cb41e18fe SHA512 b870a3faca9c8c02866f3e1856abf3d170e63876cb7cd5056167136e4f36b1c5a668e79e15fd17cb363f4c7e206a7ee2762a9296730d33526460f50de59e81ed
+DIST cinder-11.0.2.tar.gz 5794973 BLAKE2B a7b59afbe3e27a2fde28a3dcb2ba3707c67223ae7e98cb34d0ac92beb16ab8f10c07f22fda091c9db9a02fd2eff4769a6e574a94cb19df1e9506c36321a12014 SHA512 6340150aa010a4372a7e51dc976974839f89b180eef61c9307c5b477dae98c8629a3f54cbc3d114dca28ca75c715930357cfc96d08f80acaabacee8f8c0bf3a6
 DIST cinder-9.1.4.tar.gz 4195597 BLAKE2B a35b3c588d0589baf2887ebe6c9c6c4803a6819476c822fa3d314b8cb74f4fabae19cf224a3b9dc2c6255338eff6413be189e3555f5e49578451604f091169ba SHA512 8039d5208296ea54fc869fb05dd91451ac3575eb3dd2ed97d0c63120d18b67b02b835a849cd1ec3dae349920895e13665c15a6daa53f67138823053c49ab87a9
 DIST newton-cinder-policy.json 6412 BLAKE2B 90c6a2733b0c20a95375e9a588c311e48f9f189aff43ce9a89a808e6693b2f14ca0485fbea4d000674414081171989dc8050c0079e4e137f728decbdf8a5cec0 SHA512 3473b5790487bd037d54e4a1a89bab9d145bc34d137d52da2b6b311d2dfee2344fec75c6c96bc518a3e0b175fbd6cde71fb546406c0ef835898e3c1c88eb6d56
 DIST newton-cinder-volume.filters 11025 BLAKE2B ac87bb2aaab3bd492ea2f7ce7526e7ff444778ce516c71bce769f2cff1badebe7cbf520c604a0193b03f615e0d34dff21cee34f4798cc03151711b205924728b SHA512 311a636180a18bb45867d55f9d33f1eff053cc7b278b41149c58a14450ff8e6d2016d749cc3fb81d1976c4ab78f7701a908bd9c81eb6e9da31c20820a4eaff3d
diff --git a/sys-cluster/cinder/cinder-11.0.2.ebuild b/sys-cluster/cinder/cinder-11.0.2.ebuild
new file mode 100644
index 000000000000..26d79d759941
--- /dev/null
+++ b/sys-cluster/cinder/cinder-11.0.2.ebuild
@@ -0,0 +1,209 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+
+inherit distutils-r1 eutils linux-info user
+
+DESCRIPTION="Cinder is the OpenStack Block storage service, a spin out of nova-volumes"
+HOMEPAGE="https://launchpad.net/cinder"
+SRC_URI="https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/pike/cinder.conf.sample -> pike-cinder.conf.sample
+https://tarballs.openstack.org/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+api +scheduler +volume infiniband iscsi lvm mysql +memcached postgres rdma sqlite +tcp test +tgt"
+REQUIRED_USE="|| ( mysql postgres sqlite ) iscsi? ( tgt ) infiniband? ( rdma )"
+
+CDEPEND=">=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/pbr-2.1.0"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	app-admin/sudo"
+
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
+	!~dev-python/Babel-2.4.0[${PYTHON_USEDEP}]
+	>=dev-python/decorator-3.4.0[${PYTHON_USEDEP}]
+	dev-python/enum34[$(python_gen_usedep 'python2_7')]
+	>=dev-python/eventlet-0.18.4[${PYTHON_USEDEP}]
+	!~dev-python/eventlet-0.20.1[${PYTHON_USEDEP}]
+	<dev-python/eventlet-0.21.0[${PYTHON_USEDEP}]
+	>=dev-python/greenlet-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.7.5[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	virtual/python-ipaddress[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/keystonemiddleware-4.12.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-2.3[${PYTHON_USEDEP}]
+	!~dev-python/lxml-3.7.0[${PYTHON_USEDEP}]
+	>=dev-python/oauth2client-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-4.0.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-config-4.3.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-config-4.4.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-2.14.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-db-4.24.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.22.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-messaging-5.24.2[${PYTHON_USEDEP}]
+	!~dev-python/oslo-messaging-5.25.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-middleware-3.27.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-policy-1.23.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-privsep-1.9.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-privsep-1.17.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-reports-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-rootwrap-5.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-service-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.20.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-versionedobjects-1.17.0[${PYTHON_USEDEP}]
+	>=dev-python/osprofiler-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.0[${PYTHON_USEDEP}]
+	dev-python/paste[${PYTHON_USEDEP}]
+	>=dev-python/pastedeploy-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.2.2[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/python-barbicanclient-4.0.0[${PYTHON_USEDEP}]
+	!~dev-python/python-barbicanclient-4.5.0[${PYTHON_USEDEP}]
+	!~dev-python/python-barbicanclient-4.5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-glanceclient-2.8.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/python-novaclient-6.0.0[${PYTHON_USEDEP}]
+	!~dev-python/python-novaclient-7.0.0[${PYTHON_USEDEP}]
+	>=dev-python/python-swiftclient-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/retrying-1.2.3[${PYTHON_USEDEP}]
+	!~dev-python/retrying-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/routes-2.3.1[${PYTHON_USEDEP}]
+	>=dev-python/taskflow-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/rtslib-fb-2.1.43[${PYTHON_USEDEP}]
+	!~dev-python/rtslib-fb-2.1.60[${PYTHON_USEDEP}]
+	!~dev-python/rtslib-fb-2.1.61[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	sqlite? (
+		>=dev-python/sqlalchemy-1.0.10[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.5[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.6[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.7[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.8[sqlite,${PYTHON_USEDEP}]
+	)
+	mysql? (
+		>=dev-python/pymysql-0.7.6[${PYTHON_USEDEP}]
+		!~dev-python/pymysql-0.7.7[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.5[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.6[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.7[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.8[${PYTHON_USEDEP}]
+	)
+	postgres? (
+		>=dev-python/psycopg-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.5[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.6[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.7[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.8[${PYTHON_USEDEP}]
+	)
+	>=dev-python/sqlalchemy-migrate-0.11.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	~dev-python/suds-0.6[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-2.1.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-i18n-3.15.2[${PYTHON_USEDEP}]
+	>=dev-python/oslo-vmware-2.17.0[${PYTHON_USEDEP}]
+	>=dev-python/os-brick-1.15.2[${PYTHON_USEDEP}]
+	>=dev-python/os-win-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/tooz-1.47.0[${PYTHON_USEDEP}]
+	>=dev-python/google-api-python-client-1.4.2[${PYTHON_USEDEP}]
+	>=dev-python/castellan-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-1.6[${PYTHON_USEDEP}]
+	!~dev-python/cryptography-2.0[${PYTHON_USEDEP}]
+	iscsi? (
+		tgt? ( sys-block/tgt )
+		sys-block/open-iscsi
+	)
+	lvm? ( sys-fs/lvm2 )
+	memcached? ( net-misc/memcached )
+	app-emulation/qemu
+	sys-fs/sysfsutils"
+# qemu is needed for image conversion
+
+#PATCHES=(
+#)
+
+pkg_pretend() {
+	linux-info_pkg_setup
+	CONFIG_CHECK_MODULES=""
+	if use tcp; then
+		CONFIG_CHECK_MODULES+="SCSI_ISCSI_ATTRS ISCSI_TCP "
+	fi
+	if use rdma; then
+		CONFIG_CHECK_MODULES+="INFINIBAND_ISER "
+	fi
+	if use infiniband; then
+		CONFIG_CHECK_MODULES+="INFINIBAND_IPOIB INFINIBAND_USER_MAD INFINIBAND_USER_ACCESS"
+	fi
+	if linux_config_exists; then
+		for module in ${CONFIG_CHECK_MODULES}; do
+			linux_chkconfig_present ${module} || ewarn "${module} needs to be enabled"
+		done
+	fi
+}
+
+pkg_setup() {
+	enewgroup cinder
+	enewuser cinder -1 -1 /var/lib/cinder cinder
+}
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Let's track progress of this # https://bugs.launchpad.net/swift/+bug/1249727
+	nosetests -I test_wsgi.py cinder/tests/ || die "tests failed under python2.7"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	keepdir /etc/cinder
+	dodir /etc/cinder/rootwrap.d
+
+	for svc in api scheduler volume; do
+		newinitd "${FILESDIR}/cinder.initd-2" cinder-${svc}
+	done
+
+	insinto /etc/cinder
+	insopts -m0640 -o cinder -g cinder
+	doins "etc/cinder/api-httpd.conf"
+	doins "etc/cinder/logging_sample.conf"
+	doins "etc/cinder/rootwrap.conf"
+	doins "etc/cinder/api-paste.ini"
+	doins "etc/cinder/policy.json"
+	doins "etc/cinder/resource_filters.json"
+	newins "${DISTDIR}/pike-cinder.conf.sample" "cinder.conf.sample"
+	insinto /etc/cinder/rootwrap.d
+	doins "etc/cinder/rootwrap.d/volume.filters"
+
+	dodir /var/log/cinder
+	fowners cinder:cinder /var/log/cinder
+
+	#add sudoers definitions for user nova
+	insinto /etc/sudoers.d/
+	insopts -m 0440 -o root -g root
+	newins "${FILESDIR}/cinder.sudoersd" cinder
+}
+
+pkg_postinst() {
+	if use iscsi ; then
+		elog "Cinder needs tgtd to be installed and running to work with iscsi"
+		elog "it also needs 'include /var/lib/cinder/volumes/*' in /etc/tgt/targets.conf"
+	fi
+}