sys-apps/ethq: new ebuild

Displays an auto-updating per-second count of the number
of packets and bytes being handled by each queue on
a multi-queue NIC.

Signed-off-by: Vladimir Pavljuchenkov <spiderx@spiderx.dp.ua>
Package-Manager: Portage-2.3.49, Repoman-2.3.11
Signed-off-by: Michał Górny <mgorny@gentoo.org>
Close: https://github.com/gentoo/gentoo/pull/10082

4 files changed, 125 insertions, 0 deletions

diff --git a/sys-apps/ethq/Manifest b/sys-apps/ethq/Manifest
new file mode 100644
index 000000000000..e96200ec1042
--- /dev/null
+++ b/sys-apps/ethq/Manifest
@@ -0,0 +1 @@
+DIST ethq-0_5_0.tar.gz 15830 BLAKE2B b18326f1564d08f94500aa934838053a3b84b78f3d6fa90984c3730ac8922fbe3fd5141d5e9ff4a2c8db54bb8d2c2e493f5583f46b287324d4327583f29b8bf5 SHA512 989978e0dfbb553497f5325807f2d09e4e2842de9df5f5717e832312141adba3e99ef1d57dde4ac0fdd2919c9f5a0eadef5b5f76a300ab4ac7e881c8509fbbec
diff --git a/sys-apps/ethq/ethq-0.5.0.ebuild b/sys-apps/ethq/ethq-0.5.0.ebuild
new file mode 100644
index 000000000000..71eae77cf755
--- /dev/null
+++ b/sys-apps/ethq/ethq-0.5.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PV=${PV//./_}
+MY_P=${PN}-${MY_PV}
+
+inherit toolchain-funcs
+
+DESCRIPTION="Ethernet NIC Queue stats viewer"
+HOMEPAGE="https://github.com/isc-projects/ethq"
+SRC_URI="https://github.com/isc-projects/ethq/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+DEPEND="sys-libs/ncurses:0"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+
+	# Respect FLAGS
+	sed -i -e '/CXXFLAGS/s/= -O3/+=/' \
+		-e '/LDFLAGS/s/=/+=/' Makefile || die "sed failed for Makefile"
+
+	if ! use test ; then
+		sed -i '/TARGETS/s/ethq_test//' Makefile \
+			|| die "sed failed for USE flag test"
+	fi
+}
+
+src_compile() {
+	# override for ncurses[tinfo]
+	emake CXX="$(tc-getCXX)" LIBS_CURSES="$($(tc-getPKG_CONFIG) --libs ncurses)"
+}
+
+src_test() {
+	local driver
+	for driver in tests/* ; do
+		"${S}"/ethq_test "${driver##*/}" "${driver}" \
+			|| die "test failed on ${driver}"
+	done
+}
+
+src_install() {
+	einstalldocs
+	dobin ethq
+}
diff --git a/sys-apps/ethq/ethq-9999.ebuild b/sys-apps/ethq/ethq-9999.ebuild
new file mode 100644
index 000000000000..a5106e0c3579
--- /dev/null
+++ b/sys-apps/ethq/ethq-9999.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGIT_REPO_URI="https://github.com/isc-projects/${PN}.git"
+
+inherit git-r3 toolchain-funcs
+
+DESCRIPTION="Ethernet NIC Queue stats viewer"
+HOMEPAGE="https://github.com/isc-projects/ethq"
+SRC_URI=""
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+
+DEPEND="sys-libs/ncurses:0"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+
+	# Respect FLAGS
+	sed -i -e '/CXXFLAGS/s/= -O3/+=/' \
+		-e '/LDFLAGS/s/=/+=/' Makefile || die "sed failed for Makefile"
+
+	if ! use test ; then
+		sed -i '/TARGETS/s/ethq_test//' Makefile \
+			|| die "sed failed for USE flag test"
+	fi
+}
+
+src_compile() {
+	# override for ncurses[tinfo]
+	emake CXX="$(tc-getCXX)" LIBS_CURSES="$($(tc-getPKG_CONFIG) --libs ncurses)"
+}
+
+src_test() {
+	local driver
+	for driver in tests/* ; do
+		"${S}"/ethq_test "${driver##*/}" "${driver}" \
+			|| die "test failed on ${driver}"
+	done
+}
+
+src_install() {
+	einstalldocs
+	dobin ethq
+}
diff --git a/sys-apps/ethq/metadata.xml b/sys-apps/ethq/metadata.xml
new file mode 100644
index 000000000000..61adaf0931ba
--- /dev/null
+++ b/sys-apps/ethq/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>spiderx@spiderx.dp.ua</email>
+		<name>Vladimir Pavljuchenkov</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<longdescription>
+	Displays an auto-updating per-second count of the number of packets
+	and bytes being handled by each queue on a multi-queue NIC.
+	</longdescription>
+	<upstream>
+		<remote-id type="github">isc-projects/ethq</remote-id>
+	</upstream>
+</pkgmetadata>