sci-libs/indilib: add 2.0.4

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 77 insertions, 0 deletions

diff --git a/sci-libs/indilib/Manifest b/sci-libs/indilib/Manifest
index ce0c8c2c2354..7d5bc805fc4e 100644
--- a/sci-libs/indilib/Manifest
+++ b/sci-libs/indilib/Manifest
@@ -1 +1,2 @@
 DIST indilib-2.0.3.tar.gz 2713456 BLAKE2B b74f3319c744227b533616ec369cb6f379253928c1d73ef8336d122152fcb866403efe8c7aa6f65c99ba10149b0b2b43c4a86a87f82353ce045602b261b75618 SHA512 323e694f90d71cf26da8b05d60d136f2422dc12e31ec88012250faf795e67bb95da2fd729cacc5bfa7cb74cc8fe1e12a0512cb57e694c87f362a4828228db0b7
+DIST indilib-2.0.4.tar.gz 2778082 BLAKE2B 21573abeb054f6693d29e5e67908be8be06246c138dba7dd8815c80d338fe8dbc202b103454f8e9a0b97e0fa05d5464547f32a2aa6bc0fa6189ddabd1f67428c SHA512 cb8c05ed2d814350e8357dfb3fd42ce5f2db88a0d150b0feb63fcb85cadd70369bfce1600a60837e242e5815ad076923428c456f4b331ffe1a22a2c02e11ced4
diff --git a/sci-libs/indilib/indilib-2.0.4.ebuild b/sci-libs/indilib/indilib-2.0.4.ebuild
new file mode 100644
index 000000000000..d7542c61a1ac
--- /dev/null
+++ b/sci-libs/indilib/indilib-2.0.4.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P/lib/}"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="ogg rtlsdr test websocket"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/libev
+	media-libs/libjpeg-turbo:=
+	net-misc/curl
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	sci-libs/libnova:=
+	sys-libs/zlib
+	virtual/libusb:1
+	ogg? (
+		media-libs/libogg
+		media-libs/libtheora
+	)
+	rtlsdr? ( net-wireless/rtl-sdr )
+	websocket? ( dev-libs/boost:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-kernel/linux-headers )
+	test? ( >=dev-cpp/gtest-1.8.0 )
+	websocket? ( dev-cpp/websocketpp )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DINDI_BUILD_QT5_CLIENT=OFF
+		-DINDI_BUILD_SHARED=ON
+		-DINDI_BUILD_STATIC=OFF
+		-DINDI_BUILD_XISF=OFF # not packaged
+		-DUDEVRULES_INSTALL_DIR="${EPREFIX}$(get_udevdir)"/rules.d
+		$(cmake_use_find_package ogg OggTheora)
+		$(cmake_use_find_package rtlsdr RTLSDR)
+		-DINDI_BUILD_UNITTESTS=$(usex test)
+		-DINDI_BUILD_INTEGTESTS=$(usex test)
+		-DINDI_BUILD_WEBSOCKET=$(usex websocket)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# Unit tests
+	BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
+
+	# Integration tests
+	# They fail in parallel because they try to bind to the same port more
+	# than once.
+	BUILD_DIR="${BUILD_DIR}"/integs cmake_src_test -j1
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}