sci-libs/cartopy: Version bump

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/sci-libs/cartopy/Manifest b/sci-libs/cartopy/Manifest
index 15559100d5e9..0417f6eb7b58 100644
--- a/sci-libs/cartopy/Manifest
+++ b/sci-libs/cartopy/Manifest
@@ -1 +1,2 @@
 DIST cartopy-0.18.0.tar.gz 14191937 BLAKE2B bb10791ef2534dad404cc492e378161a4a078813b09d6e2c16d0d465c7dcfbaa7f24d3818cfe0f1f46e7683bdf2e00440640534835ce064492d5321489e355bc SHA512 912d5ab57c96b9e6c51b3ad26f94d77e495eb9c3a8fb8a68bdd957c11b1bc8a3ddc97e76e0d8a5ec9afca9302b01fe5753f4208ec3829df8741ee0ebbaafe30f
+DIST cartopy-0.19.0.tar.gz 11738107 BLAKE2B 129a32850947e3439505812655b0feb25f33e3b45a909be56a0093cba41acbf777be7e899b528cc910e044fc8844438283eff4d20a1433ab5ea3c58f240efa0f SHA512 5019c752fed18295048cdbe927e28040b61327414262c67c079572969e8ec3abd76f4cb0e6dd1f8ee4cfb88426cbd926ff9a2e934e8d47b8a3180bf748bd7364
diff --git a/sci-libs/cartopy/cartopy-0.19.0.ebuild b/sci-libs/cartopy/cartopy-0.19.0.ebuild
new file mode 100644
index 000000000000..236d53b0c151
--- /dev/null
+++ b/sci-libs/cartopy/cartopy-0.19.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1 virtualx
+
+MY_PV=${PV/_beta/b}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Python package for geospatial data processing and analysis"
+HOMEPAGE="https://scitools.org.uk/cartopy"
+SRC_URI="https://github.com/SciTools/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/pyshp[${PYTHON_USEDEP}]
+	sci-libs/shapely[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/pillow[jpeg,${PYTHON_USEDEP}]
+	sci-libs/gdal[python,${PYTHON_USEDEP}]
+"
+
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	sci-libs/geos
+	<sci-libs/proj-8
+"
+
+distutils_enable_tests pytest
+
+DEPEND+="test? (
+		dev-python/filelock[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/setuptools_scm_git_archive[${PYTHON_USEDEP}]
+		dev-python/flufl-lock[$PYTHON_USEDEP]
+	)"
+
+S="${WORKDIR}"/${MY_P}
+
+python_prepare_all() {
+	# drop test file requiring network access, which got not covered by markers
+	rm "${S}"/lib/cartopy/tests/mpl/test_crs.py || die
+	rm "${S}"/lib/cartopy/tests/mpl/test_gridliner.py || die
+	# prepare matplotlib backend for test suite
+	export MPLCONFIGDIR="${T}"
+	echo "backend : Agg" > "${MPLCONFIGDIR}"/matplotlibrc || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cd "${BUILD_DIR}"
+	# drop all tests needing network access
+	virtx pytest -vv -m "not network and not natural_earth" || die "test failed"
+}