net-misc/youtube-dl: bump to v2018.11.18

- EAPI bump to EAPI=7

Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>

3 files changed, 119 insertions, 1 deletions

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index bed9a122e42d..6a860eb22ff1 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -2,3 +2,4 @@ DIST youtube-dl-2017.11.15.tar.gz 2834012 BLAKE2B fd93e3923f99874be58681a886c09e
 DIST youtube-dl-2018.08.22.tar.gz 3025389 BLAKE2B e8d2d8bccab8c169d08de35544e5efb05c65799c26894807e075edfe090d36de30fea787f54d59e4fc8b671356ce2e1d9002627948fb05becc9d2e3bc634164c SHA512 ef17c744ac27b3bf547124f18a155908a66ee75f3f6fb5d7dd8a1d8da61a5a598bbade6cf0362e8c93c337dcf47750db5f56357919226430f02d0b764011ffb5
 DIST youtube-dl-2018.10.05.tar.gz 3044157 BLAKE2B c65651eebda6bd9c28245415f7aa804c78a74fa33a9717a3e9589734334ed8d12d5432eadd18d55ee46d4b51b1cacbe458c2ad175ed2e135b838fac54d468192 SHA512 b581372522d467b3277d81bdc9978352c720d4f33e0d8249cd0271eb1814a153324a5b34608d88d392bb52b1c57d0a6f425baf8377d5609810ef770839586714
 DIST youtube-dl-2018.10.29.tar.gz 3045428 BLAKE2B cf21d3113c07b7d62a373ada4a366fa61231eb8aa7f14192683451c99cf3f4f59d1abc04053359c2c3b40e7f80cfc2c5325f66a1b73196bb561a2244988f5114 SHA512 86f94acc888084348466d8aabc3711f25cbeb28c9a7afe08dcf23034d3b43d0e0a9c58dab60fe9c7eb2ab8ce2e3ce97b849e1eb11f547d173bb25dbb9df1b39f
+DIST youtube-dl-2018.11.18.tar.gz 3057924 BLAKE2B eb995cd269c3febcda950d87466df85a31128aaf95dbbd1cb9ee3d329610ffae3194c57f5063b47e49de3e387b5f60a5e10c237dc5d944ce47a6cffacab31935 SHA512 47e503c18f2db948beeda6a61b034953fab61d7d122641be7564a0f6dc0fe66ff93d6ef436c2acbcaf7255248a0b53e4df8c5ed1efca1139dc518a3ffacb737d
diff --git a/net-misc/youtube-dl/youtube-dl-2018.11.18.ebuild b/net-misc/youtube-dl/youtube-dl-2018.11.18.ebuild
new file mode 100644
index 000000000000..c28ce5a6c074
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2018.11.18.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{2_7,3_4,3_5,3_6})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://rg3.github.com/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+IUSE="+offensive test"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-python/nose[coverage(+)] )
+"
+
+S="${WORKDIR}/${PN}"
+
+python_prepare_all() {
+	if ! use offensive; then
+		sed -i -e "/..version../s|'$|+gentoo.no.offensive.sites'|g" \
+			youtube_dl/version.py || die
+		# these have single line import statements
+		local xxx=(
+			alphaporno anysex behindkink camwithher chaturbate eporner
+			eroprofile extremetube foxgay goshgay hellporno hentaistigma
+			hornbunny keezmovies lovehomeporn mofosex myvidster porn91 porncom
+			pornflip pornhd pornotube pornovoisines pornoxo ruleporn sexu
+			slutload spankbang spankwire sunporno thisav vporn watchindianporn
+			xbef xnxx xtube xvideos xxxymovies youjizz youporn
+		)
+		# these have multi-line import statements
+		local mxxx=(
+			drtuber fourtube motherless pornhub redtube tnaflix tube8 xhamster
+		)
+		# do single line imports
+		sed -i \
+			-e $( printf '/%s/d;' ${xxx[@]} ) \
+			youtube_dl/extractor/extractors.py \
+			|| die
+
+		# do multiple line imports
+		sed -i \
+			-e $( printf '/%s/,/)/d;' ${mxxx[@]} ) \
+			youtube_dl/extractor/extractors.py \
+			|| die
+
+		sed -i \
+			-e $( printf '/%s/d;' ${mxxx[@]} ) \
+			youtube_dl/extractor/generic.py \
+			|| die
+
+		rm \
+			$( printf 'youtube_dl/extractor/%s.py ' ${xxx[@]} ) \
+			$( printf 'youtube_dl/extractor/%s.py ' ${mxxx[@]} ) \
+			test/test_age_restriction.py \
+			|| die
+	fi
+
+	eapply_user
+
+	distutils-r1_python_prepare_all
+}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake test
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins youtube-dl.zsh _youtube-dl
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins youtube-dl.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "youtube-dl(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/youtube-dl/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}
diff --git a/net-misc/youtube-dl/youtube-dl-99999999.ebuild b/net-misc/youtube-dl/youtube-dl-99999999.ebuild
index 62abae9c2005..4de5d95c46fd 100644
--- a/net-misc/youtube-dl/youtube-dl-99999999.ebuild
+++ b/net-misc/youtube-dl/youtube-dl-99999999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI="7"
 PYTHON_COMPAT=(python{2_7,3_4,3_5,3_6})
 inherit bash-completion-r1 distutils-r1 git-r3 readme.gentoo-r1