net-im/err: add 6.1.8

update EAPI from 7 to 8, use PEP517, droped python 3.7

Signed-off-by: Yu Gu <guyu2876@gmail.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/net-im/err/Manifest b/net-im/err/Manifest
index 96da875a11a0..c5098d299111 100644
--- a/net-im/err/Manifest
+++ b/net-im/err/Manifest
@@ -1 +1,2 @@
 DIST err-6.1.7.tar.gz 1359383 BLAKE2B 400bbf4a4180f74993a4414dc55f07a69b34b04277fecd073bd860df9dcd5da4873949df766c0c2f6b7a43b4e87153d0aa77b0abaf95bf9702d76c3c7b290abe SHA512 cd0dadc5ff380c71631bae7711bdba7345046fbe14e369c8efa8eed98752b9ea03f6e4fa3171df257a9d76686c610e28fac5f39f7e8e107348a5746e4354694b
+DIST err-6.1.8.tar.gz 1609310 BLAKE2B e3682bfccd548c92160322287a17e26448322abd3956d464b393f333c0cc521d6d5183dab799d280603995a4508a2eb300fefb9c6159da6ed1c550247fa375d9 SHA512 5413f667ee4e121134b791f0dc8fd709ecbd9093a237b9637d282f41458c40076615ffc9167cfa95f297ae416c38b16ded8ae97aece55a81d88dc46b324ec851
diff --git a/net-im/err/err-6.1.8.ebuild b/net-im/err/err-6.1.8.ebuild
new file mode 100644
index 000000000000..847de8ea693d
--- /dev/null
+++ b/net-im/err/err-6.1.8.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+MY_PN="errbot"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Multiprotocol chatbot designed to be easily deployable and maintainable"
+HOMEPAGE="https://errbot.readthedocs.io/en/latest/"
+SRC_URI="https://github.com/errbotio/errbot/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+KEYWORDS="~amd64"
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="irc +xmpp"
+
+DEPEND="
+	acct-group/err
+	acct-user/err"
+RDEPEND="${DEPEND}
+	dev-python/ansi[${PYTHON_USEDEP}]
+	dev-python/bottle[${PYTHON_USEDEP}]
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/daemonize[${PYTHON_USEDEP}]
+	dev-python/deepmerge[${PYTHON_USEDEP}]
+	dev-python/dulwich[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/webtest[${PYTHON_USEDEP}]
+	irc? (
+		dev-python/irc[${PYTHON_USEDEP}]
+	)
+	xmpp? (
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		dev-python/pyasn1-modules[${PYTHON_USEDEP}]
+		dev-python/slixmpp[${PYTHON_USEDEP}]
+	)"
+BDEPEND="test? ( dev-python/mock[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -i -e '/pygments-markdown-lexer/d' setup.py || die
+
+	# NameError: name 'slack' is not defined
+	rm tests/backend_tests/slack_test.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local deselect=(
+		tests/commands_test.py::test_plugin_cycle
+		tests/commands_test.py::test_broken_plugin
+		tests/commands_test.py::test_backup
+		tests/plugin_management_test.py::test_check_dependencies_requi
+	)
+
+	epytest ${deselect[@]/#/--deselect }
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newinitd "${FILESDIR}"/errd.initd.2 errd
+	newconfd "${FILESDIR}"/errd.confd errd
+
+	dodir /etc/${PN}
+	keepdir /var/lib/${PN}
+	keepdir /var/log/${PN}
+	fowners -R err:err /var/lib/${PN}
+	fowners -R err:err /var/log/${PN}
+
+	insinto /etc/${PN}
+	newins errbot/config-template.py config.py
+}
+
+pkg_postinst() {
+	elog "For more backends (Hipchat, Slact, Telegram) support, use pip"
+}