net-analyzer/nagios-check_rbl: new version 1.4.1 with perl-5.26 support.

Package-Manager: Portage-2.3.6, Repoman-2.3.1

1 files changed, 53 insertions, 0 deletions

diff --git a/net-analyzer/nagios-check_rbl/nagios-check_rbl-1.4.1.ebuild b/net-analyzer/nagios-check_rbl/nagios-check_rbl-1.4.1.ebuild
new file mode 100644
index 000000000000..ab5f020ab441
--- /dev/null
+++ b/net-analyzer/nagios-check_rbl/nagios-check_rbl-1.4.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="Monitor whether or not a host is blacklisted"
+HOMEPAGE="https://github.com/matteocorti/check_rbl"
+
+MY_P="${P/nagios-/}"
+SRC_URI="${HOMEPAGE}/releases/download/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE=""
+
+# The package's INSTALL/Makefile.PL files specify its dependencies.
+#
+#   * Data::Validate::Domain (dev-perl/Data-Validate-Domain)
+#   * Data::Validate::IP (dev-perl/Data-Validate-IP)
+#   * IO::Select (dev-lang/perl)
+#   * Monitoring::Plugin (dev-perl/Monitoring-Plugin)
+#   * Monitoring::Plugin::Getopt (dev-perl/Monitoring-Plugin)
+#   * Monitoring::Plugin::Threshold (dev-perl/Monitoring-Plugin)
+#   * Net::DNS (dev-perl/Net-DNS)
+#   * Net::IP (dev-perl/Net-IP)
+#   * Readonly (dev-perl/Readonly)
+#
+RDEPEND="dev-lang/perl
+	dev-perl/Data-Validate-Domain
+	dev-perl/Data-Validate-IP
+	dev-perl/Monitoring-Plugin
+	dev-perl/Net-DNS
+	dev-perl/Net-IP
+	dev-perl/Readonly"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	perl Makefile.PL INSTALLDIRS=vendor || die
+}
+
+src_install() {
+	default
+
+	local nagiosplugindir=/usr/$(get_libdir)/nagios/plugins
+
+	# It's simplest to move this file after it's been installed.
+	dodir "${nagiosplugindir}"
+	mv "${D}"/usr/bin/check_rbl "${D}"/"${nagiosplugindir}" || die
+}