media-video/totem: Version bump to 42.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 122 insertions, 0 deletions

diff --git a/media-video/totem/Manifest b/media-video/totem/Manifest
index 537bbeac0ce6..9e11ac415eca 100644
--- a/media-video/totem/Manifest
+++ b/media-video/totem/Manifest
@@ -1 +1,2 @@
 DIST totem-3.38.2.tar.xz 2190700 BLAKE2B 3b3b8166cf674b882a3a66a5729d794489fe779944bb277fad35fe027b56270e6ef578590924309b9fe28aca0544754696acd98d31a7243a33a533abe73ed6fd SHA512 1dac3a0afe31b47147a129c70dddf7480446fc1bb5432f9cd537384e3be25da6a9b87918fa7bcf7e7cd68c8dac45e75f6b1f7c1885edefac846c52f96b40567f
+DIST totem-42.0.tar.xz 2476952 BLAKE2B 45eac2e586c3c17eab9f570812ae2c79812859635d1ef6df1d0d2c526436558dbab9581699ce86d3e2cd3048f5d65bbd1927c3faa5f7575a5468d0813ce68bcc SHA512 67872d06a7d691a23b97255c5ee5f8d90a1fdf2b36f064f26c10fb4958733772eea456aab4f0fe2c89d23ec987cf5b9c2383c97ba5bec45247953296f1cd6c4b
diff --git a/media-video/totem/totem-42.0.ebuild b/media-video/totem/totem-42.0.ebuild
new file mode 100644
index 000000000000..66b603f2b2ad
--- /dev/null
+++ b/media-video/totem/totem-42.0.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit gnome.org gnome2-utils meson virtualx xdg python-single-r1
+
+DESCRIPTION="Media player for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Videos https://gitlab.gnome.org/GNOME/totem/"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+IUSE="gtk-doc +python test"
+# see bug #359379
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+RESTRICT="!test? ( test )"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.56.0:2
+	>=x11-libs/gtk+-3.22.0:3[introspection]
+	>=gui-libs/libhandy-1.5.0:1
+	>=media-libs/gstreamer-1.6.0:1.0
+	>=media-libs/gst-plugins-base-1.6.0:1.0[pango]
+	>=media-libs/gst-plugins-good-1.6.0:1.0
+	>=media-libs/grilo-0.3.0:0.3[playlist]
+	>=dev-libs/libpeas-1.1.0[gtk]
+	>=dev-libs/totem-pl-parser-3.26.5:0=[introspection]
+	gnome-base/gnome-desktop:3=
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/cairo-1.14
+	x11-libs/gdk-pixbuf:2
+	>=dev-libs/gobject-introspection-1.54:=
+
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			>=dev-python/pygobject-2.90.3:3[${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="${DEPEND}
+	media-plugins/grilo-plugins:0.3
+	media-plugins/gst-plugins-meta:1.0
+	media-plugins/gst-plugins-taglib:1.0
+	x11-themes/adwaita-icon-theme
+	python? (
+		x11-libs/pango[introspection]
+		>=dev-libs/libpeas-1.1.0[python,${PYTHON_SINGLE_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+		')
+	)
+"
+BDEPEND="
+	dev-lang/perl
+	gtk-doc? ( >=dev-util/gtk-doc-1.14
+		app-text/docbook-xml-dtd:4.5 )
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+# perl for pod2man
+# Prevent dev-python/pylint dep, bug #482538
+
+PATCHES=(
+	"${FILESDIR}"/3.38.0-gst-inspect-sandbox.patch # Allow disabling calls to gst-inspect (sandbox issue)
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Drop pointless samplepython plugin from build
+	sed -e '/samplepython/d' -i src/plugins/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dhelp=true
+		-Denable-easy-codec-installation=yes
+		-Denable-python=$(usex python yes no)
+		-Dwith-plugins=all # in 3.34.1 only builtin and python plugins are left, and python is extra controlled by enable-python
+		$(meson_use gtk-doc enable-gtk-doc)
+		-Dgst-inspect=false
+	)
+	meson_src_configure
+}
+
+src_install() {
+	local -x GST_PLUGIN_SYSTEM_PATH_1_0= # bug 812170
+	meson_src_install
+	if use python ; then
+		python_optimize "${ED}"/usr/$(get_libdir)/totem/plugins/
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
+
+src_test() {
+	virtx meson_src_test
+}