media-tv/kodi: Cleanup old version

Package-Manager: Portage-3.0.7, Repoman-3.0.1
Signed-off-by: Craig Andrews <candrews@gentoo.org>

2 files changed, 0 insertions, 319 deletions

diff --git a/media-tv/kodi/Manifest b/media-tv/kodi/Manifest
index 843022b5aeca..cfe89c33d1e9 100644
--- a/media-tv/kodi/Manifest
+++ b/media-tv/kodi/Manifest
@@ -1,10 +1,8 @@
 DIST ffmpeg-kodi-4.0.4-Leia-18.4.tar.gz 12430413 BLAKE2B 6de6fde2c16264f851466b46f87c23c34e7d503203f69d47342d46034f153860190d196da51221f866315405c8a33325b2160283333256ee5d5e293336afae99 SHA512 c6dd75dbff7119adeeda246cfb640b5e8d3b4c242ef83e5ba070207b60f0c715c3fe3cb328d87687b70a133f122a03aba990f0e95f3aac7d5dbcee25bec59078
-DIST ffmpeg-kodi-4.3-Matrix-Alpha1.tar.gz 13478011 BLAKE2B 6219293fba86981c34c22b1a91c6dce0c298d523ecafe2e0ddce8b1ec4213d4f8f65610e4555a124a582d7fa8e858d0ad6921015fa4e639d64a02e955f7faf46 SHA512 23220650b550fe2008c38c955e10baf55e1ceaac780cf170db5349b156ac399ff3eda39509773f0c973c50083e75823b1da8e92b3751c04bb06a7f5687bef850
 DIST ffmpeg-kodi-4.3.1-Matrix-Alpha1-2.tar.gz 13477450 BLAKE2B c33a2aad8b895be3ea5be76de238680284487d38a8c22ce57f17c3944a6ba214c0dfa9ef1e4717244ff8f70f6dd640b36715842d61ddaed65867a6c096470283 SHA512 7f614d0dd2b319414cb31853be9cd52e5e81b780a4049e36470f992e78e52bcd65e99bfd268df5f8781ad030bb60f99d15bd5e8c4d7c2fd9a4011b55a3efc40c
 DIST kodi-18-libmicrohttpd-0.9.71.patch 84981 BLAKE2B e07c7df63bdfbaf9dfc5d0989adf96eb663a8c99ea11c42dfc585d8b91343a3445e9bc2f1797e845b0895e79568526e8e594a76e8cb3d7b591153a0ad45ce807 SHA512 286a1466174d847eac460b2a7a1b66b082148f2a3e91c4f5f881b909a59b8fdb2037eda074bd3c6e5dbe6a65dc2bef9f1d6746d7db2cb78d285c4b7750c366c2
 DIST kodi-18.7.tar.gz 51051040 BLAKE2B 7ff04cd0ddcf74e46eef4318cf870662b9e076b362322958a6b8019d49134e37981f7ca21b5806e38b942adc4c29ea2b25a19f46e5da3d469613cf19a29f4e8c SHA512 7e5678f5e23e8af929056a49b0ce0b992a1f53a1fe970a149610c5a24adb591085bb06cc405e8bdc6040eef853d23e99df660d7006fc1ea4e79afd3a697875c5
 DIST kodi-18.8.tar.gz 51052219 BLAKE2B 6e49b08b5e2bfe778dafb687658e82b90226a9f1c1a7827a4290d601fe4c98e5cbaabaa39563c19a2956b83ce3a76640f081a56a41dfea4d65fb8b503c6f37b0 SHA512 242eaa9144ba0d9b15f02ab41282295de76d375cf66d595e7f6687d47c996133fcf5647448dcd06759df9f30bd86cdba239720b9bdd8b57827b6f261c08c4aaa
-DIST kodi-19.0_alpha1_p20200909.tar.gz 52135793 BLAKE2B 5c67cc5f983a19cc860653c1da89053e641af1650d44a82c071deb2d57852039fb222e82530d398e316aee1ea7a9929c243017a5ef26a475d40f658de2db8d86 SHA512 3edb6302932c59ff41765a0b1b16a1757cf5197fac38bcc2eaf4f9a2683c15e7c1e4fb31a82c966cb6b6aa29e98d68d22ce006d5ff583500bf0f38522d63472a
 DIST kodi-19.0_alpha1_p20200914.tar.gz 52061486 BLAKE2B b3dbee93256394dd821cf969ef8c3fd3a8913b5d3598340b7217d5464194d91cbf6f39d4ac4a92f2d506ca0e9502cb53a3e33f4df6ae465557f909320e41f2f9 SHA512 9181f6002ca99a4c07304d71e22521c9aedd1983a0cd5cc7fa24cbfa2775ecaf55056e726332723d290eeca72d0fda3167a2b58cd8492c738f06b1a8c11b410f
 DIST libdvdcss-1.4.2-Leia-Beta-5.tar.gz 101068 BLAKE2B 283aa2cec0a2200d3569bc280cb9659e9224a6b3a77db8a35b269cd8caf1337ac9d8b92b806df66f63ef7458a46bd6261f0b8b14678b10e26644a79dcbeea5da SHA512 5185dbdbeb1bd13ea9d8723f1f4ab599d6f3102f5ba1096cd085aa1cda252c045f327c719227bba8e1b742352ade5e335106c8d0c1637a5a6b93ce661620dd7e
 DIST libdvdnav-6.0.0-Leia-Alpha-3.tar.gz 137942 BLAKE2B 7573434a0ae8e8ccabf48173f81fcde29074eb138e119a2ae9156cde3c3d8bfd716f5d0e605b97f2dcac21f570781137c8533c5ae306b51e3905822fda318355 SHA512 11c93eaacd156f8fd7dec7c43d366438b201f31ad55b2870463a9e286912b6ada08882319a021fb7992190f87b909a49f2b83e0321cc17aedc29f7fe5898fa72
diff --git a/media-tv/kodi/kodi-19.0_alpha1_p20200909.ebuild b/media-tv/kodi/kodi-19.0_alpha1_p20200909.ebuild
deleted file mode 100644
index fff81113ecd2..000000000000
--- a/media-tv/kodi/kodi-19.0_alpha1_p20200909.ebuild
+++ /dev/null
@@ -1,317 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_REQ_USE="libressl?,sqlite,ssl"
-LIBDVDCSS_VERSION="1.4.2-Leia-Beta-5"
-LIBDVDREAD_VERSION="6.0.0-Leia-Alpha-3"
-LIBDVDNAV_VERSION="6.0.0-Leia-Alpha-3"
-FFMPEG_VERSION="4.3"
-CODENAME="Matrix"
-FFMPEG_KODI_VERSION="Alpha1"
-PYTHON_COMPAT=( python3_{6,7,8,9} )
-SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz -> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz
-	https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz -> libdvdread-${LIBDVDREAD_VERSION}.tar.gz
-	https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz -> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz
-	!system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
-if [[ ${PV} == *9999 ]] ; then
-	EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
-	inherit git-r3
-else
-	GIT_COMMIT="eb609cbe43eeacf045ddf1fa303c9224e3ca0799"
-	SRC_URI+=" https://github.com/xbmc/xbmc/archive/${GIT_COMMIT}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-	S=${WORKDIR}/xbmc-${GIT_COMMIT}
-fi
-
-inherit autotools cmake desktop linux-info pax-utils python-single-r1 xdg
-
-DESCRIPTION="A free and open source media-player and entertainment hub"
-HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
-
-LICENSE="GPL-2+"
-SLOT="0"
-# use flag is called libusb so that it doesn't fool people in thinking that
-# it is _required_ for USB support. Otherwise they'll disable udev and
-# that's going to be worse.
-IUSE="airplay alsa bluetooth bluray caps cec +css dbus dvd gbm gles lcms libressl libusb lirc mariadb mysql nfs +opengl pulseaudio raspberry-pi samba systemd +system-ffmpeg test udf udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	|| ( gles opengl )
-	^^ ( gbm raspberry-pi wayland X )
-	?? ( mariadb mysql )
-	bluray? ( udf )
-	udev? ( !libusb )
-	udisks? ( dbus )
-	upower? ( dbus )
-"
-RESTRICT="!test? ( test )"
-
-COMMON_DEPEND="${PYTHON_DEPS}
-	airplay? (
-		>=app-pda/libplist-2.0.0
-		net-libs/shairplay
-	)
-	alsa? ( >=media-libs/alsa-lib-1.1.4.1 )
-	bluetooth? ( net-wireless/bluez )
-	bluray? ( >=media-libs/libbluray-1.1.2 )
-	caps? ( sys-libs/libcap )
-	dbus? ( sys-apps/dbus )
-	dev-db/sqlite
-	dev-libs/expat
-	>=dev-libs/flatbuffers-1.11.0
-	>=dev-libs/fribidi-1.0.5
-	cec? ( >=dev-libs/libcec-4.0[raspberry-pi?] )
-	dev-libs/libpcre[cxx]
-	>=dev-libs/libinput-1.10.5
-	>=dev-libs/libxml2-2.9.4
-	>=dev-libs/lzo-2.04
-	>=dev-libs/spdlog-1.5.0:=
-	dev-libs/tinyxml[stl]
-	$(python_gen_cond_dep '
-		dev-python/pillow[${PYTHON_MULTI_USEDEP}]
-		dev-python/pycryptodome[${PYTHON_MULTI_USEDEP}]
-	')
-	>=dev-libs/libcdio-2.1.0
-	>=dev-libs/libfmt-6.1.2
-	dev-libs/libfstrcmp
-	gbm? (	media-libs/mesa[gbm] )
-	gles? (
-		!raspberry-pi? ( media-libs/mesa[gles2] )
-	)
-	lcms? ( media-libs/lcms:2 )
-	libusb? ( virtual/libusb:1 )
-	virtual/ttf-fonts
-	media-fonts/roboto
-	media-libs/dav1d
-	>=media-libs/fontconfig-2.13.1
-	>=media-libs/freetype-2.10.1
-	>=media-libs/libass-0.13.4
-	!raspberry-pi? ( media-libs/mesa[egl] )
-	>=media-libs/taglib-1.11.1
-	system-ffmpeg? (
-		>=media-video/ffmpeg-${FFMPEG_VERSION}:=[dav1d,encode,postproc]
-		libressl? ( media-video/ffmpeg[libressl,-openssl] )
-		!libressl? ( media-video/ffmpeg[-libressl,openssl] )
-	)
-	mysql? ( dev-db/mysql-connector-c:= )
-	mariadb? ( dev-db/mariadb-connector-c:= )
-	>=net-misc/curl-7.68.0[http2]
-	nfs? ( >=net-fs/libnfs-2.0.0:= )
-	opengl? ( media-libs/glu )
-	!libressl? ( >=dev-libs/openssl-1.0.2l:0= )
-	libressl? ( dev-libs/libressl:0= )
-	raspberry-pi? (
-		|| ( media-libs/raspberrypi-userland media-libs/raspberrypi-userland-bin media-libs/mesa[egl,gles2,video_cards_vc4] )
-	)
-	pulseaudio? ( media-sound/pulseaudio )
-	samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
-	>=sys-libs/zlib-1.2.11
-	udf? ( >=dev-libs/libudfread-1.0.0 )
-	udev? ( virtual/udev )
-	vaapi? (
-		x11-libs/libva:=
-		opengl? ( x11-libs/libva[opengl] )
-		system-ffmpeg? ( media-video/ffmpeg[vaapi] )
-		vdpau? ( x11-libs/libva[vdpau] )
-		wayland? ( x11-libs/libva[wayland] )
-		X? ( x11-libs/libva[X] )
-	)
-	virtual/libiconv
-	vdpau? (
-		|| ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
-		system-ffmpeg? ( media-video/ffmpeg[vdpau] )
-	)
-	wayland? (
-		>=dev-cpp/waylandpp-0.2.3:=
-		media-libs/mesa[wayland]
-		>=dev-libs/wayland-protocols-1.7
-	)
-	webserver? ( >=net-libs/libmicrohttpd-0.9.55[messages(+)] )
-	X? (
-		media-libs/mesa[X]
-		x11-libs/libX11
-		x11-libs/libXrandr
-		x11-libs/libXrender
-		system-ffmpeg? ( media-video/ffmpeg[X] )
-	)
-	x11-libs/libdrm
-	>=x11-libs/libxkbcommon-0.4.1
-	xslt? ( dev-libs/libxslt )
-	zeroconf? ( net-dns/avahi[dbus] )
-"
-RDEPEND="${COMMON_DEPEND}
-	lirc? ( app-misc/lirc )
-	udisks? ( sys-fs/udisks:2 )
-	upower? ( sys-power/upower )
-"
-DEPEND="${COMMON_DEPEND}
-	app-arch/bzip2
-	app-arch/xz-utils
-	dev-lang/swig
-	dev-libs/crossguid
-	dev-libs/rapidjson
-	dev-util/cmake
-	dev-util/gperf
-	media-libs/giflib
-	>=media-libs/libjpeg-turbo-2.0.4:=
-	>=media-libs/libpng-1.6.26:0=
-	test? ( >=dev-cpp/gtest-1.10.0 )
-	virtual/pkgconfig
-	virtual/jre
-	x86? ( dev-lang/nasm )
-"
-
-CONFIG_CHECK="~IP_MULTICAST"
-ERROR_IP_MULTICAST="
-In some cases Kodi needs to access multicast addresses.
-Please consider enabling IP_MULTICAST under Networking options.
-"
-
-pkg_setup() {
-	check_extra_config
-	python-single-r1_pkg_setup
-}
-
-src_unpack() {
-	if [[ ${PV} == *9999 ]] ; then
-		git-r3_src_unpack
-	else
-		default
-	fi
-}
-
-src_prepare() {
-	cmake_src_prepare
-
-	# avoid long delays when powerkit isn't running #348580
-	sed -i \
-		-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
-		xbmc/platform/linux/*.cpp || die
-
-	# Prepare tools and libs witch are configured with autotools during compile time
-	AUTOTOOLS_DIRS=(
-		"${S}"/tools/depends/native/TexturePacker/src
-		"${S}"/tools/depends/native/JsonSchemaBuilder/src
-	)
-
-	local d
-	for d in "${AUTOTOOLS_DIRS[@]}" ; do
-		pushd ${d} >/dev/null || die
-		AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
-		popd >/dev/null || die
-	done
-	elibtoolize
-
-	# Prevent autoreconf rerun
-	sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
-		"${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
-		"${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
-		|| die
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
-		-DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
-		-DENABLE_ALSA=$(usex alsa)
-		-DENABLE_AIRTUNES=$(usex airplay)
-		-DENABLE_AVAHI=$(usex zeroconf)
-		-DENABLE_BLUETOOTH=$(usex bluetooth)
-		-DENABLE_BLURAY=$(usex bluray)
-		-DENABLE_CCACHE=OFF
-		-DENABLE_CEC=$(usex cec)
-		-DENABLE_DBUS=$(usex dbus)
-		-DENABLE_DVDCSS=$(usex css)
-		-DENABLE_INTERNAL_CROSSGUID=OFF
-		-DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
-		-DENABLE_INTERNAL_FSTRCMP=OFF
-		-DENABLE_INTERNAL_GTEST=OFF
-		-DENABLE_INTERNAL_UDFREAD=OFF
-		-DENABLE_CAP=$(usex caps)
-		-DENABLE_LCMS2=$(usex lcms)
-		-DENABLE_LIRCCLIENT=$(usex lirc)
-		-DENABLE_MARIADBCLIENT=$(usex mariadb)
-		-DENABLE_MICROHTTPD=$(usex webserver)
-		-DENABLE_MYSQLCLIENT=$(usex mysql)
-		-DENABLE_NFS=$(usex nfs)
-		-DENABLE_OPENGLES=$(usex gles)
-		-DENABLE_OPENGL=$(usex opengl)
-		-DENABLE_OPTICAL=$(usex dvd)
-		-DENABLE_PLIST=$(usex airplay)
-		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
-		-DENABLE_SMBCLIENT=$(usex samba)
-		-DENABLE_TESTING=$(usex test)
-		-DENABLE_UDEV=$(usex udev)
-		-DENABLE_UDFREAD=$(usex udf)
-		-DENABLE_UPNP=$(usex upnp)
-		-DENABLE_VAAPI=$(usex vaapi)
-		-DENABLE_VDPAU=$(usex vdpau)
-		-DENABLE_XSLT=$(usex xslt)
-		-Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz"
-		-Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_VERSION}.tar.gz"
-		-Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz"
-		-DPYTHON_INCLUDE_DIR="$(python_get_includedir)"
-		-DPYTHON_LIBRARY="$(python_get_library_path)"
-	)
-
-	use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
-
-	if use system-ffmpeg; then
-		mycmakeargs+=( -DWITH_FFMPEG="yes" )
-	else
-		mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
-	fi
-
-	if use gbm; then
-		mycmakeargs+=(
-			-DCORE_PLATFORM_NAME="gbm"
-			-DGBM_RENDER_SYSTEM="$(usex opengl gl gles)"
-		)
-	fi
-
-	if use wayland; then
-		mycmakeargs+=(
-			-DCORE_PLATFORM_NAME="wayland"
-			-DWAYLAND_RENDER_SYSTEM="$(usex opengl gl gles)"
-		)
-	fi
-
-	if use raspberry-pi; then
-		mycmakeargs+=( -DCORE_PLATFORM_NAME="rbpi" )
-	fi
-
-	if use X; then
-		mycmakeargs+=(
-			-DCORE_PLATFORM_NAME="x11"
-			-DX11_RENDER_SYSTEM="$(usex opengl gl gles)"
-		)
-	fi
-
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile all
-}
-
-src_test() {
-	# see https://github.com/xbmc/xbmc/issues/17860#issuecomment-630120213
-	KODI_HOME="${BUILD_DIR}" cmake_build check
-}
-
-src_install() {
-	cmake_src_install
-
-	pax-mark Em "${ED}"/usr/$(get_libdir)/${PN}/${PN}.bin
-
-	newicon media/icon48x48.png kodi.png
-
-	rm "${ED}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
-	dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
-		usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
-
-	python_domodule tools/EventClients/lib/python/xbmcclient.py
-	python_newscript "tools/EventClients/Clients/KodiSend/kodi-send.py" kodi-send
-}